一)我们大多数的股民并不完全了解“公式编辑器”,“公式编辑器”好比是一个工作"母床",
通它可以制造出各式各样的零件,利用编辑器可以编写出相应的分析条件,
这种方法是在技术分析当中最为常用的方法之一。
体现自己独特的(思路)想法.
例1筹码突破
主筹估算:=EMA(WINNER(C)*70,3),COLORRED;
散筹估算:=EMA((WINNER(C*1.1)-WINNER(C*0.9))*70,3),COLOR009900;
买:CROSS(主筹估算,散筹估算);
例2天河彩虹
换手:=VOL/CAPITAL*100;
H1:=EMA(CLOSE,8);
H2:=EMA(H1,20);
XG:CROSS(H1,H2)AND 换手>5;
例3领头羊
白色:=SMA(HIGH,21,2)*1.05,;
黄色:=SMA(LOW,21,2)*0.95;
粉色:=SMA(LOW,5,1);
绿色:=SMA(CLOSE,2,1),;
波段买入:=IF(CROSS(绿色,粉色),白色*1.05,粉色);
领头羊:=IF(CROSS(绿色,白色),白色*1.10,黄色);
领头羊>黄色 OR 波段买入>粉色;
1. 什么是条件选股?
就是按照您的设定的条件,比如您有一些好的心得和方法,
2. 什么是参数?
M最常用的数填在“缺省”一栏,例如你最喜欢用10日均线,那就填10吧。
3 什么是周期?
允许不同喜好的使用者选择不同的分析时间基数。
例一:一根K线有四个价格组成:
最高价:HIGH 收盘价:CLOSE 最低价:LOW 开盘价:OPEN
成交量:VOL 成交额:AMO
例二:两条均线交叉,就专门设定了一条函数来描述两条线交叉:CROSS(X,Y)
CROSS(X,Y)表示X向上穿过了Y CROSS(Y,X)表示Y向上穿过了X
k上穿(下穿) 均线选股方法:
A上穿均线:cross(A,ma(A,2)); 或cross(A,ref(A,1));
A下穿均线:cross(ma(A,2),A); 或cross(ref(A,1),A);
例三:前面的CLOSE,还是VOL,都表示当天,或者您使用的不是日线,那就表示本周期的数据,
那么前几天的怎么表示呢? REF(X,M)
如:REF(Close,5)表示5天前的收盘; REF(Vol,10)表示10天前的成交量;
例四:如果我想把两个条件(同时满足)怎么办?AND
X AND Y就表示条件X和条件Y
例五 HHV(X,M)表示X在M天内的最高值!
例:HHV(HIGH,150)每日最高价在150天内的最大值
HHV(VOL,150)每日成交量在150天内的最大值
LLV(X,M)表示X在M天内的最小值
例:LLV(LOW,10)每日最低价在10天内的最小值
HHV(VOL,20)每日成交量在20天内的最大值
例六 COUNT(X,N)表示统计在N天内满足条件X的有几天。
多头排列--良好的上升趋势
5/10/30日均线依次从上而下的排列,这种情况维持一段时间,
假设我们这里定为4天以上:
AA:=MA(CLOSE,5);
BB:=MA(CLOSE,10);
CC:=MA(CLOSE,30);
T1:=AA>BB AND BB>CC;
COUNT(T1,4 )=4
例七 阳线成交量:=REF(V,阳线天数);
阳线天数:=BARSLAST(阳线);
阳线:=
例 八各路人马持仓量公式:
换手:=V*100/CAPITAL;
主力:=MA(换手,3);
大户:=MA(换手,10);
中户:=MA(换手,15);
散户:=MA(换手,30);
均量:=(主力+大户+中户+散户)/4;
主力净能量:(主力-均量)COLORRED,NODRAW;
大户净量:(大户-均量)COLORMAGENTA,NODRAW;
中户净量:(中户-均量)COLORYELLOW,NODRAW;
ADVANCE――上涨家数----返回该周期上涨家数。用法:ADVANCE(本函数仅对大盘有效)
DECLINE――下跌家数----返回该周期下跌家数。用法:DECLINE(本函数仅对大盘有效)
BUYVOL――主动性买盘----返回主动性买单量。用法:BUYVOL
当本笔成交为主动性买盘时,其数值等于成交量,否则为0
(本函数仅个股在分笔成交分析周期有效)
SELLVOL――主动性卖单----返回主动性卖单量。用法:SELLVOL
当本笔成交为主动性卖盘时,其数值等于成交量,否则为0
(本函数仅个股在分笔成交分析周期有效)
BACKSET――向前赋值----将当前位置到若干周期前的数据设为1。
BACKSET(X,N),若X非0,则将当前位置到N周期前的数值设为1。
DMA――动态移动车前均----求动态移动平均。
用法:DMA(X,A),求X的动态移动平均。
若Y=DMA(X,A)则 Y=A*X+(1-A)*Y',
其中Y'表示上一周期Y值,A必须小于1。
REF――目前的----引用若干周期前的数据。
REF(CLOSE,1)表示上一周期的收盘价,在日线上就是昨收
SUM――累积----求总和。
SUM(X,N),统计N周期中X的总和,N=0则从第一个有效值开始。
SUM(VOL,0)表示统计从上市第一天以来的成交量总和
SUMBARS―― 累加到指定周期数----向前累加到指定值到现在的周期数。
用法:SUMBARS(X,A):将X向前累加直到大于等于A,返回这个区间的周期数
例如:SUMBARS(VOL,CAPITAL)求完全换手到现在的周期数
例九 低位密集
A1:=COST(85);
A2:=COST(15);
A3:=A1-A2;
A4:=(A1+A2)/2;
A5:=A3/A4*100<10;
B1:=HHV(H,120);
B2:=LLV(L,120);
B3:=B1-B2;
B4:=(A4-B2)<B3/2;
A5 AND B4;
例十 K线的描述
close>open;阳线
close<open;阴线
open>ref(close,1);高开
open<ref(close,1);低开
open>ref(high,1);跳空高开(high为最高价)
open<ref(low,1);跳空低开(low为最低价)
连续n日收阳线
up:=close>open;
count(up,n)=n;
连续n天上涨
count(close>ref(close,1),n)=n;
二)选股公式 的编造
1.按照主菜单-工具-公式管理-选择-“技术指标”-点击“新建”,点击:“确认”。
第一步:“工具”栏中选中“公式管理器”
第二步:我们现在选择“新建”一个“条件选股”公式,结果出现了下面的编辑栏!然后在里面写上您的条件!
第三步:按照说明书上的步骤选股就行了!
1)、在条件选股中点击“新建”;
2)、原来MA5:MA(CLOSE,5);表示的是一条指标线,
可是现在我们在条件选股当中只要引用它,不需要把它画出来。所以我们在冒号的后面加一个符号=,
表示等会要引用它:MA5:=MA(CLOSE,5);这个在的公式编辑中,叫做“中间表达式”。
例X=1;Y=X+1;
Y=?
2.、如果选择:“主图叠加”,我们的指标线会与K线图显示在同一个图形框中,
现在我们的指标线大都显示在其下方,即“副图”中;
1)、参数可以有,也可以没有,但是鼓励大家设置参数,这是非常好的习惯;
2)、一个句子完了,别忘了以分号结尾;
3) 你的公式写得对不对,可以通过“测试公式”来检查,如果错了,它会告诉你错在哪里
3. 编写最常用的均量和均价线 :
5日平均线=(今天收盘价+昨天收盘价+.....--5天前的收盘价)/5;
10日平均线=(今天收盘价+昨天收盘价+......+10天前的收盘价)/10;
1)MA1=MA(CLOSE,5);
MA2=MA(CLOSE,10);
“MA”表示的就是计算平均值。在括号内写上计算的对象和计算的时间长度。
2)均量线???
MA1:MA(VOL,5);
MA2:MA(VOL,10);
4. .如何编写BIAS指标? 原理??
以当日的均线价格为准,股价和均价之间的差距称为乖离程度,以乖离程度除以均价的百分比就是乖离率。
当日股价与10日均线的乖离率=(当日股价-10日均价)/10日均价*100;
当日股价与20日均线的乖离率=(当日股价-20日均价)/20日均价*100;
BIAS1:(CLOSE-MA(CLOSE,10))/MA(CLOSE,10)*100;
5. “KD指标发生了黄金交叉,并且D<20”
T1:=“KDJ,K”;--引用K线;
T2:=“KDJ,D”;--引用D线;
CROSS(T1,T2)AND T2<20;
6. 出手就赢 60MA由向下调头向上 指标低位
RSV:= (CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
CROSS(K,D)AND K <40 AND D>30;
ma(c,60)>ref(ma(c,60),1);
三)放量、缩量、上涨、下跌、收阳、收阴
1 放量:
1)今日比昨日的成交量放大了1倍:
VOL/REF(VOL,1)>2;
2)今日的五日均量比前五天的五日均量放大了3倍:
AA:=MA(VOL,5);
BB:=REF(AA,5);
AA/BB>4;
3)今天的成交量达到了整个流通盘的10%以上:
VOL/CAPITAL>10/100;
2.缩量:
1)今日比昨日的成交量缩小了1倍:
VOL/REF(VOL,1)<0.5;
2)今日的五日均量比前五天的五日均量缩小了一半:
AA:=MA(VOL,1)<0.5;
BB:=REF(AA,5);
AA/BB<0.5;
3)今天的成交量不足整个流通盘的0.5%:
VOL/CAPITAL<0.5/100;
3.上涨:
1)今日涨幅达到了7%以上:
CLOSE/REF(CLOSE,1)>1.07;
2)十日均价继续上涨:
AA:=MA(CLOSE,10);
BB:=REE(AA,1);
AA>BB;
4.下跌:同上面3的表达方式一样,将方向改变了而已:
5.收阳、收阴:
1)当天收阳:CLOSE>OPEN;当天收真阳:C>O AND C>REF(C,1);
2)当天收阴:CLOSE<OPEN;
6.高开、低开:
1)当天股价高开,言下之意开盘高于昨日收盘:OPEN>REF(CLOSE,1);
2)当天股价低开:OPEN<REF(CLOSE,1);
7.跳空:跳空亦有向上和向下两种:
1)向上跳空:OPEN>REF(HIGH,1);
2)向下跳空:POEN<REF(LOW,1);
8 放2倍量上攻(涨幅大于7%)
AA:=VOL/REF(VOL,1)>2;
BB:=CLOSE/REF(CLOSE,1)>1.07;
AA AND BB;
9 高开高走:
AA:=OPEN>REF(CLOSE,1);
BB:=CLOSE>OPEN;
AA AND BB;
10.向上跳空之后两天内并未回补
(实际上就是前天发生了跳空缺口,这两天的最低价一直在两天前的最高价之上。)
1)AA:=REF(OPEN,1)>REF(HIGH,2);
BB:=REF(LOW,1)>REF(HIGH,2);
CC:=LOW>REF(HIGH,2);
AA AND BB AND CC;
2)更简单的方法:
COUNT(LOW>REF(HIGH,2),2)=2;
11 放量(2倍).突破底部横盘整理创新高!
“长期”设定为150天;“横盘”设定股价在150日均线上下15%波动;放量;并且股价创下150天以来的历史新高!
1)首先用公式描述放量 ,将会使用5日均量来进行比较,
成交量比昨日成交量放大两倍;
V1:=MA(VOL,5); V2:=VOL/REF(V1,1)>2;
2)、长期横盘
a、PZ1是当天150日均价: PZ1:=MA(CLOSE,M);
b、PZ2是150日的最高价; PZ2:=HHV(HIGH,M);
c、PZ3是150日的最低价; PZ3:=LLV(LOW,M);
d、PZ4是150日的最高价和150日均价的距离的百分比,; PZ4:=(PZ2-PZ1)/PZ1;
PZ5刚好相反是最低价和均价的差的百分比 PZ5:=(PZ1-PZ3)/PZ1;
e、设为股价在150日均线上下15%波动,也就是PZ4、PZ5都小于0.15;
PZ:=REF(PZ4,1)<0.5 AND REF(PZ5,1)<0.15;
3)今天创下历史新高,也就是今天的最高价是150天内的最高价! TP1:HHV(HIGH,M);
TP:=HIGH=TP1;
最后的逻辑判断式就是我们的最后结论! V2 AND PZ AND TP(参数M=150天)
四)
1. 20均线由下跌状态刚刚转为上升前5日是下跌状态
ma(c,20)>ref(ma(c,20),1) and count(ma(c,20)<ref(ma(c,20),1),6)=5;
2. 60分钟VOL三线粘合金叉的选股公式
cross(ma(vol,5),ma(vol,10)) and cross(ma(vol,5),ma(vol,20));{60分钟周期}
3. 上涨放量,下跌缩量的选股公式
a1:=barslast(c>o);
a2:=barslast(c<o);
ref(v,a1)>ref(v,a2);
4.三日换手率之和的排序公式及三日累计涨跌幅之和的排序公式
sum(vol/capital,3);{换手}
close/ref(close,3);{涨幅}
5.一个阶段(如10天)涨幅大于10的个股公式
close/ref(close,10)>1.10;
6.macd底背离预警公式
LLV(L,55)=L AND NOT(LLV("MACD.MACD",55)="MACD.MACD");{MACD底背离};
7.DDX连续放大三天 三天涨幅小于5?
last("ddx.ddx">ref("ddx.ddx",1))>=3 and close/ref(c,3)<1.05;
8.成交量比前一日放大,MACD金叉之后,第一根红柱,K线阳包阴,涨幅小于4个点。站在60天均线之上
vol>ref(vol,1) and cross("macd.diff","macd.dea") and close>open and ref(c,1)<ref(o,1) and c>ref(h,1) and o<ref(low,1) and close/ref(c,1)<1.04 and close>ma(c,60);
9.股价与量比底背离的选股公式
ma(c,3)=llv(ma(c,3),20) and ma(v,3)>ref(ma(v,3),1);
10.股价一底比一底低,MACD的DIFF一底比一底高(2个底),(不用金叉或二次金叉),
llv("macd.diff",10)>llv("macd.diff",20) and l=llv(l,20);
11.10日线和5日线,kdj中的j和macd中的diff值均上翘,发出买入信号
aa:=ma(c,5)>ref(ma(c,5),1) and ref(ma(c,5),1)<ref(ma(c,5),2) and ma(c,10)>ref(ma(c,10),1) and ref(ma(c,10),1)<ref(ma(c,10),2) and
"kdj.j">ref("kdj.j",1) and ref("kdj.j",1)<ref("kdj.j",2) and "macd.diff">ref("macd.diff",1) and ref("macd.diff",1)<ref("macd.diff",2);
DRAWICON(aa,l,7 );
12.一个股价突破最近高点的选股公式,指的是最近的一个波段的高点
N:=20;
cross(close,ref(hhv(c,N),1));{突破N最高点,N可以自设}
13.在2天里出现KDJ周线金叉,KDJ日线金叉的选股公式
count(cross("kdj.k","kdj.j") and cross("kdj.k#week","kdj.j#week"),2)=1;
14 一是突破盘整;二是突破前高;三是突破平台
W1:=C=HHV(C,20);
W2:=BARSLAST(W1);
W3:=IF(W2>0,REF(C,W2),REF(C,W2));
W4:=CROSS(C,REF(W3,1));
W4 AND COUNT(W4,5)=1;
15数绿柱子
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
均线向上:=EMA(C,N1)>=REF(EMA(C,N1),1) AND EMA(C,N2)>=REF(EMA(C,N2),1);
绿柱:=REF(MACD,1)<REF(MACD,2) AND REF(MACD,2)<REF(MACD,3) AND REF(MACD,3) <=0 AND MACD<=0 AND REF(MACD,4) >=0;
选股:均线向上 AND 绿柱;
就调整N1或N2为60即可。)
16、周内涨停过票
ZTB1:=C/REF(C,1)>1.095AND C/REF(C,1)<1.11;
ZTB:=COUNT(ZTB1,5)>0;
ZTB;
17、0轴上的票
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
BARSLASTCOUNT(DIF>=0 AND DEA >=0)>=5
AND MACD>0;
18股价是25天以来新低.
xg:c<ref(llv(c,25),1);
19要求是(量大)换手率达到3左右,涨幅>7个点
xg:v/capital*100>3 (c/ref(c,1)>1.07;
20kdj的J从上向下穿越O轴发出信号
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1),COLORWHITE;
D:=SMA(K,3,1),COLORYELLOW;
J:=3*K-2*D,COLORFF00FF;
xg:cross(0,j);
215日均线向上 流通盘小于5000万换手率大于3的选股公式
lt:CAPITAL/100<5000;
换手:=VOL*100/CAPITAL<3;
w1:ma(c,5)>ref(ma(c,5),1);
xg:lt换手w1;
22选周线跳空缺口的个股。周期选周线
xg:LOW>REF(HIGH,1);
23 连续三天高开高走的选股公式
count(o>ref(c,1)c>o,3)=3;
24 n天内曾经至少有m个涨停
count(c/ref(c,1)>1.09,n)>=m;
25 连续3天,每天的最低价都比前一天高
count(l>ref(c,1),3)=3;
26跳空高开收阳线
LOW>REF(HIGH,1)c>o;
27涨停过300日线的选股公式
c/ref(c,1)>1.09cross(c,ma(c,300));
28跳空高开后,三天内没有回补缺口
ref(LOW,2)>REF(HIGH,3)l>ref(LOW,2);
29连续n天收阳线
UP:=CLOSE>OPEN;
COUNT(UP,N)=N;
30连续三涨停
A:=C/REF(C,1)>1.095;
XG:EVERY(A,3);
31macd后金叉高于前金叉
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
JC:=CROSS(DIFF,DEA)AND DEA<0;
JJ:=BARSLAST(JC);
QC:=CROSS(DIFF,DEA)AND COUNT(JC,30)=2;
REF(DEA>REF(DEA,JJ),1)AND QC;
REF(DEA<REF(DEA,JJ),1)QC;
32 MACD在零轴下二次金叉选股
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
低位金叉:=CROSS(DIFF,DEA) AND DIFF<-0.1;
JCCOUNT:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
二次金叉:CROSS(DIFF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1;
联系客服