清理autorun.inf的批处理

    清理硬盘的时候，发现去年没事时写的一个清理autorun.inf的批处理，拿出来给大家用用，呵呵！

复制下面的代码，粘贴到记事本里另存为BAT的文件，双击运行就可以了。

转贴请注明出处，那个改我那个title，我和谁急，哈哈~~~~~~  

@echo off

title 清理AUTORUN.INF --- BY 佛爱我羊 [2007]

cls

color fc

echo.&echo.

for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    if exist %%a:\autorun.inf (
      echo 发现%%a盘上有AUTORUN.INF,正在清理...
      attrib %%a:\autorun.inf -s -h -r
      for /f "tokens=2* delims==" %%b in (%%a:\autorun.inf) do (
        if exist %%a:\%%b (
          attrib %%a:\%%b -s -h -r
          del %%a:\%%b
          echo 清理了%%a盘上AUTORUN.INF相关联的%%b
        )
      )
      del %%a:\autorun.inf
      echo %%a盘上AUTORUN.INF清理成功！
    ) else (
      echo %%a盘上没有发现AUTORUN.INF。
    )
    echo.&echo.
  )
)

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\">nul
if %ERRORLEVEL%==0 (
  echo Y|reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\" /f>nul
  echo 磁盘卷装入点清理完成！)

echo.&echo.&echo 完成清理，按任意键退出！&pause>nul