//------------------------------------------------------------------------
// 简称: XTCS_ZONG_TS_KingKeltner
// 名称: 金肯特纳(版主在原有自带系统基础上进行二次改编)
策略说明:
基于肯特纳通道的突破系统
系统要素:
1、基于最高价、最低价、收盘价三者平均值计算而来的三价均线
2、基于三价均线加减真实波幅计算而来的通道上下轨
入场条件:
1、三价均线向上,并且价格上破通道上轨,开多单
2、三价均线向下,并且价格下破通道下轨,开空单
出场条件:
1、持有多单时,价格下破三价均线,平多单
2、持有空单时,价格上破三价均线,平空单
*/
Params
Numeric avgLength(40);// 三价均线参数
Numeric atrLength(20);// 真实波幅参数
Numeric Lots(0);// 交易手数
Numeric N(2);//(改编)添加了三均线上下通道ATR的倍数,可自行调节
Numeric xiansi(0);//参数设置成1,可显示图表画线显示
Vars
NumericSeries movAvgVal(0);// 三价均线参数
NumericSeries upBand(0);// 通道上轨
NumericSeries liquidPoint(0);// 出场条件
NumericSeries dnBand(0);// 通道下轨
Begin
// 集合竞价和小节休息过滤
If(!CallAuctionFilter()) Return;
// 三价均线
movAvgVal = Average((High + Low + Close)/3,avgLength);
// 通道上轨
upBand = movAvgVal + N*AvgTrueRange(atrLength);//
// 通道下轨
dnBand = movAvgVal - N*AvgTrueRange(atrLength);
// 出场条件
liquidPoint = movAvgVal;
// 画线
If(xiansi==1) //参数设置成1,可显示图表画线显示
{
PlotNumeric("movAvgVal",movAvgVal,0,Blue);
PlotNumeric("upBand",upBand,0,Yellow);
PlotNumeric("dnBand",dnBand,0,White);
}
// 三价均线向上,并且价格上破通道上轨,开多单
If(MarketPosition != 1 )
{
If( movAvgVal[1] > movAvgVal[2])
{
If(High >= upBand[1])
{
Buy(Lots,Max(Open,upBand[1]));
}
}
}
// 持有多单时,价格下破三价均线,平多单
If(MarketPosition == 1 )
{
If(BarsSinceEntry >= 1 )
{
If(Low <= liquidPoint[1])
{
Sell(0,Min(Open,liquidPoint[1]));
}
}
}
//--------------------------------------------------------------------
// 三价均线向下,并且价格下破通道下轨,开空单
If(MarketPosition != -1 )
{
If( movAvgVal[1] < movAvgVal[2])
{
If( Low <= dnBand[1])
{
SellShort(Lots,Min(Open,dnBand[1]));
}
}
}
// 持有空单时,价格上破三价均线,平空单
If(MarketPosition == -1 )
{
If( BarsSinceEntry >= 1)
{
If( High >= liquidPoint[1])
{
BuyToCover(0,Max(Open,liquidPoint[1]));
}
}
}
End
//------------------------------------------------------------------------------------
接下来以此模型来分析一下做程序化交易的一些心得与体会,(此模型仅供分析使用,切记如果您用来交易应正视风险客观存在,盈亏自负。)
//-----------------------------------------------------------------------------------
此模型在12个品种上进行组合测试,如下图
具体个别品种信号图如下:
组合测试报告一览表:
//--------------------------------------------------------------------------------------------
以下是总体组合的资金曲线走势图:
????为什么要做组合的理由是,单一品种走出一波行情是需要时间的,并且在品种没有行情的时候很少有获利机会。通过分散化投资组合。就可以得到更多的交易机会,充分利用资金的利用率。
如果不进行品种组合,只做单一品种,那么它的资金曲线是很难实现相对稳健上涨,具体的资金曲线如下:
以上单品种的资金曲线图就像物理学的运动波一样, 如果你对物理学有一定的研究应该不难理解运动波的叠加可以起到对冲的效果。 而组合后的上涨的资金曲线又好比是生物学原理,万物的发展和行情一样,总会在不断的重复着规律,交易是门学问。 我们应该顺应市场的发展规律,严控资金风险,保持着客观理性的投资理念再进行投资。
联系客服