Excel有哪些常用的Excel函数？

HI，大家好，我是星光。

众所周知，日期和时间是数据分析中最重要的维度之一，在函数系列图文教程里，咱们也花费了5篇左右的篇幅来详细介绍它们，今天做个总结，推荐收藏备用，当需要日期或时间类数据计算时，不妨打开此贴搜索看看。

先来看日期类常用函数。

♢01
=TODAY()
计算当前的系统日期

♢02
=NOW()
计算当前系统日期和时间

♢03
=DATE(2019,10,1)
将指定年月日转换为系统规定格式的日期。

♢04
=INT(NOW())
计算日期+时间混合数据中的日期。

比如2020-2-6 9:12:36，返回结果2020-2-6

♢05
=DAY(TODAY())
计算当前日期是几号

♢06
=MONTH(TODAY())
计算当前日期的月份

♢07
=YEAR(TODAY())
计算当前日期的年份

♢08
=WEEKDAY(TODAY(),2)
计算今天是星期几，返回数字，比如5。

♢09
=TEXT(TODAY(),'AAAA')
计算今天是星期几，返回字符串星期几，比如星期五。

♢10
=EDATE(TODAY(),1)
计算当前日期之后一个月后的日期

♢11
=EOMONTH(TODAY(),1)
计算下个月最后一天的日期

♢12
=EOMONTH(TODAY(),-1)+1
计算当前日期月初第一天的日期

♢13
=EOMONTH(TODAY(),0)-TODAY()
计算今天到本月底还有多少天

♢14
='12-31'-'1-1'+1
计算今年有几天

♢15
=TODAY()-'1-1'+1
计算今天是今年的第几天

♢16
=WORKDAY(TODAY(),1)
计算下个工作日是哪天

♢17
=EOMONTH(NOW(),0)-TODAY()
计算这个月还有几天

♢18
=DAY(EOMONTH(NOW(),1))
计算下个月有几天

♢19
=WORKDAY(TODAY(),30)
计算从今天开始，30个工作日（不包含双休日）之后是哪天？

♢20
=WORKDAY(TODAY(),30,B2:B8)
计算从今天开始，30个工作日（不包含礼拜六和礼拜天，也不包含B2:B8单元格保存的特殊日期，比如国庆节）之后是哪天？

♢21
=WORKDAY.INTL(TODAY(),30,'0000111',B2:B8)
计算从今天开始，30个工作日（不包含星期5、6、7，也不包含B2:B8单元格保存的特殊日期，比如国庆节）之后是哪天。

'0000111'~7位数字分别代表星期1~7。0代表工作日1代表休息日。

♢22
=A1-B1
计算A1和B1两个日期相差的天数

♢23
=NETWORKDAYS(B1,B2)
计算B1和B2单元格两个日期相差的工作日数（扣除周末双休）

♢24
=NETWORKDAYS(B1,B2,D2:D8)
计算B1和B2单元格两个日期相差的工作日数（扣除周末双休和D2:D8区域的特殊日期，比如节假日等）

♢25
=NETWORKDAYS.INTL(B1,B2,'0000001',D2:D8)
计算B1和B2单元格两个日期相差的工作日数（扣除周末单休+D2:D8单元格内的特殊日期，比如国庆节）

♢26
=DATEDIF(A2,B2,'m')
计算两个日期相差的整月数

♢27
=DATEDIF(A2,B2,'y')
计算两个日期相差的整年数

♢28
=DATEDIF(A2,TODAY(),'y')
计算年龄（假设A2是出生日期）

♢29
=DATEDIF(A2,B2,'ym')
忽略日和年，计算两日期相差月数

♢30
=DATEDIF(A2,B2,'yd')
忽略年，计算两日期相差天数

♢31
=WEEKNUM(NOW())
计算今天是本年度的第几周

♢32
=IF(COUNT(-'2-29'),'是','否')
计算今年是不是闰年

♢33
=DATEDIF('2008-2-28',TODAY(),'m')
计算自2008年2月28日到今天有几个月

♢34
=MONTH(MONTH(TODAY())*10)
计算今天属于第几季度

♢35
=COUPDAYBS(NOW(),'9999-1',4,1)+1
计算今天是本季度的第几天

♢36
=COUPDAYS(NOW(),'9999-1',4,1)
计算当前季度有几天

♢37
=HOUR(NOW())
计算当前是几点

♢38
=MINUTE(NOW())
计算当前分钟

♢39
=SECOND(NOW())
计算当前是几秒

♢40
=TEXT(NOW(),'hh:mm:ss')
计算当前几点几分几秒

♢41
=MOD(NOW(),1)
还是计算当前几点几分

♢42
= NOW()-TODAY()
还还是计算当前是几点几分

♢43
=TIME(6,6,6)
合并时、分、秒。计算结果为6:06 AM

♢44
=TEXT('2018-1-6 19:30'-'2018-1-4 19:35:48','[hh]:mm:ss')
计算加班时长。

……