很惭愧，一直没给大家什么例子，估计会用的人不多，抛砖引玉了，源码都给大家了，大家爱怎么折腾怎么折腾去吧！！！
公式名：K线分型分笔分段中枢
功能：K线分型分笔分段中枢
说明:本来打算做成主图的，但大智慧者中好像主图的K线不能去掉，而飞狐中可以。。。
本图看到的所有K线都是经过包含关系处理的, 只显示高低值，以及K线的方向（有种特殊的情况没处理，为毛这么做，一下解释不清，欢迎大家拍砖）
红色表示上涨K线，黄色表示上涨包含处理的K线，绿色表示下跌K线，青色表示下跌包含K线
白色框表示顶分型 蓝色框表示底分型
黄色的线表示的是笔 蓝色的线表示的是段
紫红色的框表示的上涨走势的中枢，青色的框表示的是下跌走势的中枢, 只会标注已结束走势的中枢。
紫红色空心五角星表示的是未封闭的上涨缺口，紫红色实心五角星表示的已封闭的上涨缺口
绿色空心五角星表示的是未封闭的下跌缺口，绿色实心五角星， 只会显示5F及以上图的缺口
适用软件: 大智慧 （飞狐自己改啊
别拍我）
插件版本: 缠论插件3.0及以上
下为源码：（注该源码主要为演示，所有很多有用的没有的一起给出来了，大家按需改，懒点的全部复制就可以了）
Ma5:ma(C,5);
Ma10:ma(C,10);
{布林曲线}
MID :MA(CLOSE,26),linethick0;
UPPER:MID + 2*STD(CLOSE,26),linethick0,coloryellow, dotline;
LOWER:MID - 2*STD(CLOSE,26),linethick0,colorgreen, dotline;
收口:=UPPER-LOWER;
partline(MID,MID>=ref(MID,1),rgb(255,255,0),MID<ref(MID,1),rgb(0,255,0)),linethick1, dotline;
partline(UPPER,UPPER>=ref(UPPER,1),rgb(255,255,0),UPPER<ref(UPPER,1),rgb(0,255,0)),linethick1, dotline;
partline(LOWER,LOWER>ref(LOWER,1),rgb(255,255,0),LOWER<=ref(LOWER,1),rgb(0,255,0)),linethick1, dotline;
{
partline(UPPER,收口>=ref(收口,1),rgb(255,255,0),收口<ref(收口,1),rgb(0,255,0)),linethick1, dotline;
partline(LOWER,收口>=ref(收口,1),rgb(255,255,0),收口<ref(收口,1),rgb(0,255,0)),linethick1, dotline;
}
kx:="chanlun@kxian"; {这个放第一个 要不会出问题滴-_-\~~}
kxg:="chanlun@kxg";
kxd:="chanlun@kxd";
kxfx:="chanlun@kxfx";
kxno:"chanlun@kxno", linethick0, coloryellow;
kxnobh:"chanlun@kxnobh", linethick0, coloryellow;
笔:="chanlun@bi";
bilast:"chanlun@bilast", linethick0, coloryellow;
段:="chanlun@duan";
duanlast:"chanlun@duanlast", linethick0, coloryellow;
中枢:="chanlun@zs";
zszg:="chanlun@zszg";
zszd:="chanlun@zszd";
zsgg:="chanlun@zsgg";
zsdd:="chanlun@zsdd";
zszz:="chanlun@zszz";
zsks:="chanlun@zskslast";
zsjs:="chanlun@zsjslast";
zstype:="chanlun@zstype";
bifx:=-REF(笔,bilast);
duanfx:=-REF(段,duanlast);
kxqj:="chanlun@kxqj";
fxqj:ref(kxqj,bilast), linethick0, coloryellow;
{TT:"chanlun@TT", linethick0, colorwhite;}
{画中枢Begin}
{以背景方式画}
{
STICKLINE(zszg>zszd AND duanfx=1, zszg, zszd, 20, 502), colorf00ff0;
STICKLINE(zszg>zszd AND duanfx=-1, zszg, zszd, 20, 502), colore6002d;
}
{以直线方式画}
{上涨中枢}
DRAWLINE(zsks=1 AND duanfx=1, zszg, zsjs=1 AND duanfx=1, zszg, 0), colormagenta, linethick2;
DRAWLINE(zsks=1 AND duanfx=1, zszd, zsjs=1 AND duanfx=1, zszd, 0), colormagenta, linethick2;
STICKLINE(zsks=1 AND duanfx=1, zszg, zszd, 1 AND duanfx=1, -501), colormagenta, linethick2;
STICKLINE(zsjs=1 AND duanfx=1, zszg, zszd, 1 AND duanfx=1, 501), colormagenta, linethick2;
{下跌中枢}
DRAWLINE(zsks=1 AND duanfx=-1, zszg, zsjs=1 AND duanfx=-1, zszg, 0), colorCyan, linethick2;
DRAWLINE(zsks=1 AND duanfx=-1, zszd, zsjs=1 AND duanfx=-1, zszd, 0), colorCyan, linethick2;
STICKLINE(zsks=1 AND duanfx=-1, zszg, zszd, 1 AND duanfx=-1, -501), colorCyan, linethick2;
STICKLINE(zsjs=1 AND duanfx=-1, zszg, zszd, 1 AND duanfx=-1, 501), colorCyan, linethick2;
{中枢震荡监视器}
DRAWLINE(zsks=1, zszz, zsjs=1, zszz, 0), coloryellow;
{画中枢END}
{显示缺口BEGIN}
{只显示5F及5F级别以上图的缺口}
kxqk:="chanlun@kxqk";
{最后未封闭的最后一个上涨（下跌）缺口到现在的周期}
kxqkup:BARSLAST(kxqk=1), linethick0, colorMagenta;
kxqkdn:BARSLAST(kxqk=-1), linethick0, colorGreen;
{缺口}
DRAWTEXT(kxqk=1, l*0.992, '☆'), colorMagenta, align1 ; {未封闭上涨缺口}
DRAWTEXT(kxqk=2, l*0.992, '★'), colorMagenta, align1 ; {已封闭上涨缺口}
DRAWTEXT(kxqk=-1, h*1.008, '☆'), colorGreen, align1, valign2; {未封闭下跌缺口}
DRAWTEXT(kxqk=-2, h*1.008, '★'), colorGreen, align1, valign2; {已封闭下跌缺口}
{显示缺口END}
{画K线Begin}
{缠论K线 已经包含处理}
STICKLINE(kxfx>1, kxg, kxd, 2, 1), coloryellow;
STICKLINE(kxfx<1, kxg, kxd, 2, 1), colorF0F000;
STICKLINE(kxfx=1, kxg, kxd, 2, 1), colorred;
STICKLINE(kxfx=-1, kxg, kxd, 2, 1), colorgreen;
{顶底分型}
STICKLINE(kx>0, kxg, kxd, 5, 1), colorwhite;
STICKLINE(kx<0, kxg, kxd, 5, 1), colorblue;
{笔段}
STICKLINE(笔=1, kxg, kxd, 5, 1), colorgreen, linethick3;
STICKLINE(笔=-1, kxg, kxd, 5, 1), colorred, linethick3;
STICKLINE(段=1, kxg, kxd, 5, 0), colore66878, linethick2;
STICKLINE(段=-1, kxg, kxd, 5, 0), color00cccc, linethick2;
{画K线END}
{画笔段}
drawline(笔=1,h,笔=-1,l,0),coloryellow;
drawline(笔=-1,l,笔=1,h,0),coloryellow;
drawline(段=1,h,段=-1,l,0),colorblue, linethick2;
drawline(段=-1,l,段=1,h,0),colorblue, linethick2;
{趋势 类趋势 扩展 扩张 提示}
drawline(REF(段,1)=1 AND zstype=3,h,段=-1 AND zstype=3,l,0),colorgreen, linethick2;
drawline(REF(段,1)=-1 AND zstype=3,l,段=1 AND zstype=3,h,0),colorred, linethick2;
{笔高低点 周期 力度 提示}
DRAWTEXT(笔=1, h, ''+h+'/T'+bilast+'/+'+(h-REF(l,bilast))), coloryellow, align1, valign2;
DRAWTEXT(笔=-1, l, ''+l+'/T'+bilast+'/'+(l-REF(h,bilast))), colorCyan, align1;
{当下提示 周期}
DRAWTEXT(BARSTATUS=2 AND bifx=1 AND bilast>4, h*1.008, 'T'+bilast+'/+'+(c-REF(l,bilast))), colorMagenta, align0, valign2;
DRAWTEXT(BARSTATUS=2 AND bifx=-1 AND bilast>4, l*0.992,'T'+bilast+'/'+(c-REF(h,bilast))), colorGreen, align0;
{以下主要演示取笔段中枢数据的方法}
{前N个高点和低点(笔)}
{
bigglast:="chanlun@bigglast";
bigg1:ref(h, bigglast), linethick0, coloryellow;
bigg2:ref(bigg1, bigglast), linethick0, coloryellow;
bigg3:ref(bigg2, bigglast), linethick0, coloryellow;
biddlast:="chanlun@biddlast";
bidd1:ref(l, biddlast), linethick0, colorcyan;
bidd2:ref(bidd1, biddlast), linethick0, colorcyan;
bidd3:ref(bidd2, biddlast), linethick0, colorcyan;
}
{取前一段的数据}
{
dgglast:="chanlun@duangglast";
dgg1:ref(h, dgglast),linethick0, coloryellow;
dddlast:="chanlun@duanddlast";
ddd1:ref(l, dddlast),linethick0, colorcyan;
}
{取前一个中枢的数据}
{
zszg1:ref(zszg, zsjs),linethick0, coloryellow;
zszd1:ref(zszd, zsjs),linethick0, coloryellow;
};
{版本信息Begin}
vsnNO:="chanlun@VERSION";
vsnDate:="chanlun@DATE";
vsnSTR:= '版本:'+vsnNO+'.'+vsnDate;
{vsnSTR1:= ' 作者:goodpp2012@gmail.com';}
vsnSTR1:='';
DRAWTEXTREL( 5, 950, vsnSTR+vsnSTR1), colormagenta, linethick2;
{版本信息End};
效果示例:
