问题：假设有张学生成绩表(tb)如下:
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
想变成(得到如下结果)：
姓名 语文 数学 物理
---- ---- ---- ----
李四 74 84 94
张三 74 83 93
建表并插入数据
if OBJECT_ID('tb2') IS NOT NULL
drop table [dbo].[tb2]
GO
create table tb2(姓名 varchar(10) , 课程 varchar(10) , 分数 int)
insert into tb2 values('张三' , '语文' , 74)
insert into tb2 values('张三' , '数学' , 83)
insert into tb2 values('张三' , '物理' , 93)
insert into tb2 values('李四' , '语文' , 74)
insert into tb2 values('李四' , '数学' , 84)
insert into tb2 values('李四' , '物理' , 94)
--SQL SERVER 2000 静态SQL,指课程只有语文、数学、物理这三门课程。(以下同)
select 姓名 as 姓名 ,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理
from tb2 group by 姓名
--SQL SERVER 2000 动态SQL,指课程不止语文、数学、物理这三门课程。(以下同)
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' ,
max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb2) as a
set @sql = @sql + ' from tb2 group by 姓名'
exec(@sql)
