系列20我们已经介绍了重复测量资料的方差分析,今天接着介绍定量数据的非参数秩和检验及其SAS实现。实际上很多统计书是按照方法来进行讲解,通常在定性数据的卡方检验之后介绍非参数秩和检验,因为非参数秩和检验不仅适用于不适用于参数检验条件的定量数据,还适用于一些定性数据的分析。在此,我们结合数据分析的实操,就按照定量数据分析的检验方法讲解完成后,再讲解定性数据的检验方法。
图9-4 定量数据假设检验方法选择
3.1单样本的Wilcoxon秩和检验
*===单样本非参数秩和检验;
PROC UNIVARIATE DATA=NPAR1 MU0=5.12 NORMAL;
VAR SMI;
RUN;
图9-41 单样本非参数检验数据的正态性检验结果
图9-42 单样本非参数检验结果
图9-41的正态性检验结果显示:W=0.818032,P=0.0002;D=0.192744,P<0.0100,按α=0.10水准拒绝H0,即不服从正态分布。图9-42的单样本非参数检验结果显示:S=210.5,P<0.0001,拒绝H0,该样本所来自总体的SMI测量值与已知总体的SMI测量值的差异有统计学意义。
3.2配对样本比较的Wilcoxon秩和检验
*===配对样本非参数秩和检验;
PROC UNIVARIATE DATA=NPAR2 NORMAL;
VAR D;
RUN;
图9-43 配对样本差值正态性检验结果
图9-44 配对样本非参数检验结果
图9-43的正态性检验结果显示:W=0.875074,P=0.0758;D=0.23347,P=0.0706,按α=0.10水准拒绝H0,即数据不服从正态分布。图9-44的单样本非参数检验结果显示:S=-21.5,P=0.00566,按α=0.05水准不拒绝H0,还不能认为两各方法的测量结果有差异。
3.3两独立样本比较的Wilcoxon秩和检验
*====两组独立样本非参数秩和检验;
*===正态性检验;
PROC UNIVARIATE DATA=NPAR3 NORMAL;
CLASS GROUP;
VAR SMI;
RUN;
*===两独立样本非参数秩和检验;
PROC NPAR1WAY DATA=NPAR3 WILCOXON;
CLASS GROUP;
VAR SMI;
RUN;
图9-45 两独立样本非参数检验结果
图9-46 两独立样本非参数检验Wilcoxon结果
图9-47 两独立样本非参数检验Kruskal-Wallis结果
图9-48 两独立样本非参数检验结果
*===完全随机设计多样本非参数秩检验;
*===正态性检验;
PROC UNIVARIATE DATA=NPAR4 NORMAL;
CLASS GROUP;
VAR RD;
RUN;
*===非参数秩和检验;
PROC NPAR1WAY DATA=NPAR4 WILCOXON;
CLASS GROUP;
VAR RD;
RUN;
图9-49完全随机设计多样本Wilcoxon得分结果
图9-50 完全随机设计多样本Kruskal-Wallis检验结果
图9-51 完全随机设计多样本数据箱式图
*===两两比较;
PROC RANK DATA=NPAR4 OUT=RESULT;
VAR RD;
RANKS R;
PROC ANOVA DATA=RESULT;
CLASS GROUP;
MODEL R=GROUP;
MEANS GROUP/LSD;
RUN;
图9-52 完全随机设计多样本两两比较结果
*====随机区组设计的非参数秩检验;
*===第一种方法:PROC FREQ过程步实现;
PROC FREQ DATA=NPAR5;
TABLES BLOCK*GROUP*RATE / SCORES=RANK CMH2 NOPRINT;
RUN;
图9-53 随机区组设计多样本数据非参数检验结果
*===第二种方法:PROC RANK和PROC GLM过程步实现,及两两比较结果;
PROC SORT DATA=NPAR5 OUT=RE1;
BY BLOCK;
RUN;
PROC RANK DATA=RE1 OUT=RE2;
VAR RATE;
BY BLOCK;
RANKS R;
RUN;
PROC GLM DATA=RE2;
CLASS GROUP BLOCK;
MODEL R=GROUP BLOCK;
LSMEANS GROUP/STDERR PDIFF;
RUN;
QUIT;
图9-54 随机区组设计多样本数据非参数检验结果(二)
图9-55 随机区组设计多样本数据非参数检验两两比较结果
PROC GLM 过程产生的R2 与(υ总-υ区组)之积,即为Friedman 检验结果,图9-54给出R2 =0.631329,υ总-υ区组=31-7=24,0.631329×24= 15.151896≈15.1519,通过计算与PROC FREQ过程步给出的统计量是一致的。图9-55是LSMEANS语句给出的两两结果,图中两要红色线显示A与B组、C与D组间的差异没有统计学意义。
整理不易,欢迎点亮再看哦!
参考文献:
[1] 陈希孺, 柴根象. 非参数统计教程[M].上海:华东师范大学出版社,1993.
[2] L.沃塞曼著, 吴喜之译. 现代非参数统计[M]. 北京: 科学出版社,2008.
[3] Marfio F. Triola. ElementaryStatistics[M]. New York: Christine Stavrou, 2010.
[4] 夏庄坤, 徐唯 , 潘红莲, 等. 深入解析SAS——数据处理、分析优化与商业应用[M].
----------------------------------------------
----------------------------------------------
精鼎特邀
联系客服