别做那个“泄密”的人！Excel常用「数据脱敏」公式汇总，大厂都在用！

你有没有这样的经历？

为什么每每注册一个网站，立马便会有无数的广告推销来给你打电话。

这就是“数据泄密”。

在日常工作中，经常也会涉及到各类姓名、手机号、身份证号等信息，为了防止“数据外泄”，在发送给别人的时候往往需要进行脱敏处理。

什么是“脱敏处理”？

数据脱敏是指对某些敏感信息进行数据变形，实现隐私数据的可靠保护。

简单点来说就是将部分内容替换成星号“*”。

今天就来给大家介绍一些Excel中常用的数据脱敏公式。

注意：文中的姓名、手机号、身份证号码均为虚拟。

第一类：姓名脱敏

规则：保持姓名字数不变的情况下，只显示姓氏（复姓只显示第一个字），其他信息都用*代替。

这类问题的特点是显示的字数固定，需要用*代替的字数不固定，下面介绍几个常用的公式。

公式1：=LEFT(A2,1)&REPT("*",LEN(A2)-1)

公式中的LEFT(A2,1)是截取姓名中的第一个字，REPT("*",LEN(A2)-1)的意思是将“*”重复姓名的字数-1次。

当LEFT的第二参数为1时可以省略，因此公式也可以修改为=LEFT(A2)&REPT("*",LEN(A2)-1)。

公式2：=REPLACE(A2,2,LEN(A2)-1,REPT("*",LEN(A2)-1))

这个公式主要利用了REPLACE函数实现数据中的内容替换，REPLACE函数有四个参数，函数结构是：REPLACE（要进行替换的文本，从第几个字开始替换，要替换的字数，替换成什么内容）。

在本例中要进行替换的文本就是姓名所在的单元格，按要求是从第二个字开始替换，LEN(A2)-1表示要替换的字数比姓名的字数少一个，REPT("*",LEN(A2)-1)表示要替换的内容，这个和公式1是一样的。

公式3：=SUBSTITUTE(A2,RIGHT(A2,LEN(A2)-1),REPT("*",LEN(A2)-1))

这个公式是利用SUBSTITUTE函数实现数据中的内容替换，函数结构是SUBSTITUTE (要替换的文本,旧文本,新文本,[替换第几个])。

与前两个公式的差别主要是第二参数，RIGHT(A2,LEN(A2)-1)表示姓名中第二个字后面的内容。关于SUBSTITUTE函数的详细讲解可以参考之前的教程：SUBSTITUTE函数

第二类：手机号脱敏

规则：将手机号的中间4位用*代替

这类问题的特点是要显示的内容和用*代替的内容长度都是固定的，下面介绍几个常用的公式。

公式1：=LEFT(B2,3)&"****"&RIGHT(B2,4)

这个公式很好理解，分别提取左边的三位LEFT(B2,3)和右边的四位RIGHT(B2,4)，再用&将四个*连接起来即可。

这个公式也可以改变为=MID(B2,1,3)&"****"&MID(B2,8,4)

用MID函数取代LEFT和RIGHT，实际上还是同一个思路。

公式2：=REPLACE(B2,4,4,"****")

REPLACE在前面已经介绍了，公式很好理解，这里就不重复了。

公式3：=SUBSTITUTE(B2,MID(B2,4,4),"****")

公式4：=TEXT(C2,"000****0000")

这个公式是利用了TEXT函数中的数字占位符“0”，将指定位置的数字用*显示。

这方面的知识可以参考教程TEXT函数用法

第三类：身份证号码脱敏

规则：将身份证号码的最后5位用*代替

这类问题与手机号脱敏的特点差不多，区别是对字符串右边的内容进行替换。解决的公式和原理也都类似，下面仅列举常用的公式，不再一一解释了。

公式1：=LEFT(B2,13)&"*****"

公式2：=REPLACE(B2,14,5,"*****")

公式3：=SUBSTITUTE(B2,RIGHT(B2,5),"*****")

公式4：=TEXT(C2,"0!*****")

写在最后：

用公式处理后的数据，还需要将其粘贴为数值，然后再删除原始数据。

数据脱敏不同于数据加密，虽然二者都有保护数据的作用，但是数据加密并没有对数据本身做处理，也就是说，只要将数据解密后就可以看到原始数据。而数据脱敏是不可逆的，脱敏后的数据无法再得到原始数据，因此做好原始数据的备份，这一点非常重要！