轻松学LOOKUP函数，10大经典案例！

大家都熟悉VLOOKUP，觉得VLOOKUP是查找之王，其实LOOKUP要比VLOOKUP更加强大和用法多元化，让我们通过10个案例让你感受一下LOOKUP查询的魅力！

案例01 | 查询提成比例！

=LOOKUP(B2,$F$2:$G$6)

公式说明：

这个应该是LOOKUP最基本的用法了，返回小于等于查询值最近接值的 对应内容！ 这里的查找值：销售金额，最接近值：小于等于销售金额所有的阈值中最大值，返回：销售比例，也就是选择区域的最后一列！

案例02 |  最后一个有内容的单元格值

查询每种水果，最近销售金额！

=LOOKUP(1,0/(B$2:B$10<>""),B$2:B$10)

公式说明：

1、0/逻辑值，如果逻辑值部分是TRUE，那么就是0，否则就是错误值

2、LOOKUP过滤掉和查询内容类型不一致的数据，剩下的第二参数都是比1小的，都是0，但是LOOKUP默认升序，所以在他眼中，后面的0比前面的0大，所以返回最后一个0 对应的值！

3、 有了他，我们可以实现很多动态数据区域的功能，比如自动获取区域大小来做数据透视表等等！

案例03 |  最后的文本

=LOOKUP("座",$B$1:$B$15)

公式说明：

1、LOOKUP是查询小于等于查询值的最大值、

2、汉字也有大小，这里“座”，你可以认为是一个比较大的汉字（按拼音靠后！）

案例04 | 最后的数值

=LOOKUP(9E+307,$B$1:$B$15)

公式说明：

最大的汉字，上面的案例我们已经讲过，那么9e+307 这个数，你因为也猜到了，你可以认为是Excel中比较大的数，一般够用了，常见的我们可以使用9^9 来代替，所以9^9也比较常见！

案例05 | 单条件查询

=LOOKUP(1,0/($B$2:$B$15=D2),$A$2:$A$15)

公式说明：

1、VLOOKUP是查询满足条件的第一个值，LOOKUP是查询满足条件的最后一个值，如果满足条件的结果只有一个，那么二者结果一致！

2、如果我们知道了编码想查询名称，只要换一下区域即可！

案例06 | 多条件查询

=LOOKUP(1,0/($A$2:$A$12=F1)/($B$2:$B$12=$F$2),$C$2:$C$12)

公式说明：

1、相对于单条件，多条件的情况下，我们可以选择连除的方式，当然你也会经常看到一些教程是 (条件1)*(条件2） 连乘，都是可以的！

2、如果有多个结果，同样是返回最后一个满足条件的值！

案例07 | 填充合并单元格

=LOOKUP("做",$A$2:A2)

公式说明：

1、这里利用的是最后一个文本值，如果你的内容文本和数值混合，可以考虑使用最后一个非空内容套路即可！

2、合并单元格只有左上角的单元格有值，其他都是空，这点要明白

3、$A$2:A2 注意这里的写法，前面绝对引用，后面相对引用，下拉区域逐步扩大！

关于引用基本概念，不是很精通的同学必读：【精通Excel基础之引用方式】

案例08 | 提取数值

=-LOOKUP(1,-LEFT(A2,ROW($1:$10)))

公式说明：

1、left公式部分是依次截取采购信息1-10位内容形成的数值，你可以认为是内容的一款连续区域吧 跟连续单元格有点类型！

2、-LEFT也就是把截取的内容转成负数，文本报错顾虑，剩下都比1小，所以肯定返回最大的，最后通过外面的 符号来转成正常的结果！

案例09  | 内存数组构建

数组公式：

=LOOKUP(ROW($A$2:$A$12),ROW($A$2:$A$12)/(A2:A12<>""),$A$2:$A$12)

公式说明：

1、比较经典的套路了！利用行号/除以是否为空，得到的就是合并单元格左上角的有内容的单元格行号，第一参数是全部行高，依次查询比自己小的有内容单元格，返回对应的A列内容

2、内存数组，可以进一步参加下一步计算，很多时候用来代替辅助列，在内存中构建好想要的辅助列！ 

案例10 |  内存数组单列转多行多列

数组公式：

=LOOKUP((ROW(1:4)-1)*3+COLUMN(A:C)+1,ROW($A$2:$A$13),$A$2:$A$13)

公式说明：

通过重构LOOKUP第一参数，我们可以把任意一行或者一列转成多行多列的内存数组，方便后续计算，这个就很强大了！

本文由“壹伴编辑器”提供技术支持

关注我，每天精彩学不停！