关于指标的用法，是一个非常简单而又非常复杂的问题。说到简单，可以说每个人都会用，说其复杂，可能对同一指标，一百个人有一百种理解和用法。因此本文只能就指标的基本使用提供一些思路，供初学者了解公式时参考。
为了介绍方便，我将指标大致划分这样几类，均线类，柱线类，形态类，趋向类，乖离类。在实际中按着不同的要求可有多种分类方式，比如主图，副图，江恩轮，画线，引用公式类等等，并且很多指标都不是单一类型，而是几种类型的复合体，这里就不细分了。
一、均线类
均线类的指标多应用于主图。均线是根据一定时期内的股价(成交量等)的平均值绘制出的一条曲线,周期不同绘出的曲线也不一样,常见的有5日、10日、20日、60日、120日、250日等，主图中所见的趋势线都是均线，但计算的方法和计算的基础会有所不同。
例一、常用均线
a5:ma(c,5);
a10:ma(c,10);
a30:ma(c,30);
a60:ma(c,60);
a120:ma(c,120);
a250:ma(c,250);
应用原则，若均线趋势向上，且短期均线在长期均线的上方，股价一般会沿续上升趋势。若短期均线从下方上穿长期均线称为金叉，为买入信号。上升途中股价走在平均线之上，股价下跌没有跌破平均线就反弹也为买进信号。上升中股价走在平均线之上，且离均线越来越远，股价会随时产生获利回吐的卖压，此时短线应考虑卖出股票。均线系统可以对股价产生助涨或助跌的作用，若股价站稳均线之上，均线就会对股价有支撑作用，反之就会对股价造成压力。操作上长期均线的参考意义更大，若120日或250日均线由下降趋势渐渐走平,并开始向上翘头,预示着牛市即将来临。经过一个时期上涨，长期均线走平或拐头向下，说明趋势走坏，或熊市来临。
有人为了战胜庄家，并不愿意用这些均线，通过修改参数形成自己独特的研判方式。比如短线进出的习惯用5分钟线，30分钟线等，长期趋势判断则用周线、月线等，即使用日线却改为21日、55日等，随心所欲。但不论如何修改，只是个人风格不同，均线的运用本质并没有改变。
例二、在均线上加入信号
{新股经X线}
X1:EMA(C,7),colorRED;
X2:EMA(c,21),color44bb00;
X3:EMA(X2,21),colorF00FF0;
x4:ema(x3,27),colorFF0000;
x5:ema(x2,100),colorFFFF00;
X6:=REF(CLOSE,1);
X7:=SMA(MAX(C-X6,0),6,1)/SMA(ABS(C-X6),6,1)*100;
DRAWTEXT(CROSS(76,X7)AND L<X1,H*1.01,'卖出');
DRAWTEXT(ALL(C>O,3)AND REF(H,1)<X1 AND H>X1 AND X1<X5,L,'买入');
DRAWICON(COUNT(H<X1,4)=3 AND X1>REF(X1,1),L*0.98,1);
DRAWTEXT(CROSS(X1,X4)AND X1>X2 AND X2>X3,X4,'追涨');
DRAWICON(COUNT(L>X1,4)=3 AND X1<REF(X1,1),H*1.02,2);
X5之前是著名的《股经X线》源码（第6行被我舍去了），后面的是应网友要求增加的提示信号。增加信号部分，实际上就是对公式的理解消化和摸索规律的过程。当然这里的信号并不全面，比如均线向上发散状的研究、金叉的研究等。
例三、均线的布林式平均
临界线:=WMA(CLOSE,13);
VAR1:=POW(CLOSE-临界线,1);
VAR2:=MA(VAR1,13);
VAR3:=SQRT(VAR2);
阻力线:临界线+1.96*VAR3;
支撑线:临界线-1.96*VAR3;
PARTLINE(临界线>REF(临界线,1) AND 阻力线<>支撑线,临界线),LINETHICK2,colorFF;
PARTLINE(临界线<REF(临界线,1),临界线),LINETHICK2,colorFF00;
PARTLINE(阻力线=支撑线,临界线),LINETHICK2,colorFF0000;
这是一个将13日均线加入系数平均，然后再分别乘心系数形成的布林式趋势线。这类公式虽然没有标识信号，实际是有规律可循的。以主轴线为例，红色持股，绿色持币，兰色观望。如图：
{本文为理想论坛博主「大庆老杨」的帖子，转载请注明出处。
原文链接: https://www.55188.com/thread-2878366-1-1.html}
二、柱线类
实际应该叫柱状类。此类公式多应用于副图，主图偶尔可见。它的典型代表是成交量。其基本特征是通过柱线的长短高低或者颜色的变化表达人们对股票的判断。
例一、 看盘VOL 原公式如下：
A:=v*100/capital;
MA(A,120),COLOR996633,POINTDOT;
MA(A,2),COLORYELLOW,POINTDOT;
主力:MA(A,9),COLORGREEN,POINTDOT;
大户:MA(A,17),COLORRED,POINTDOT;
散户:MA(A,34),COLORF2E9E7,POINTDOT;
STICKLINE(MA(A,120)>0,0,MA(A,120),4,0),COLOR996633;
STICKLINE(MA(A,2)>0,0,MA(A,2),4,0),COLORYELLOW;
STICKLINE(主力>0,0,主力,4,0),COLORGREEN;
STICKLINE(大户>0,0,大户,4,0),COLORRED;
STICKLINE(散户>0,0,散户,4,0),COLORF2E9E7;
我们先来分析这个公式的基础是什么，首句是换手率，之后的5行全是对首行的平均，最后是将这些均线画成柱线。由此可以确定，这是一个以成交量为主体，加上流通盘因素来反映股票运行动态的。
为了显示数字而又要隐去均线，均线部分用了POINTDOT点状线修饰。但这只是方法之一，感兴趣的朋友可根据所用股软换个其它方式。
那么这个公式怎么用呢？我将其加了几个字：
A:=v*100/capital;
长均换手:MA(A,120),COLOR996633,POINTDOT;
巨幅换手:MA(A,2),COLORYELLOW,POINTDOT;
主力:MA(A,9),COLORGREEN,POINTDOT;
大户:MA(A,17),COLORRED,POINTDOT;
散户:MA(A,34),COLORF2E9E7,POINTDOT;
STICKLINE(MA(A,120)>0,0,MA(A,120),4,0),COLOR996633;
STICKLINE(MA(A,2)>0,0,MA(A,2),4,0),COLORYELLOW;
STICKLINE(主力>0,0,主力,4,0),COLORGREEN;
STICKLINE(大户>0,0,大户,4,0),COLORRED;
STICKLINE(散户>0,0,散户,4,0),COLORF2E9E7;
加上文字后就好理解了，详见图示。
例二、紫风鱼身
A1:=MA(C,1);
A5:=MA(C,5);
DEA:=EMA(((SLOPE(CLOSE,21) * 20) + CLOSE),42);
紫风鱼身:(A1-A5);
多空趋势:=(A1-DEA);
STICKLINE(紫风鱼身>0 AND 多空趋势>=0,多空趋势*(-1),0,8,0),colorFFFFFF;
STICKLINE(多空趋势>0,多空趋势,0,8,0),color0888FF;
STICKLINE(多空趋势<0,多空趋势,0,8,0),colorFF9909;
STICKLINE(紫风鱼身>0,紫风鱼身,0,5,0),colorFFFFFF;
STICKLINE(紫风鱼身<0,紫风鱼身,0,5,0),colorFFFFFF;
STICKLINE(紫风鱼身>0,紫风鱼身,0,3,0),color0111FF;
STICKLINE(紫风鱼身<0,紫风鱼身,0,3,0),color009000;
这是一个将股价均线转换成柱线表示的一个例子，原理与MACD一致。
使用原则：鱼身成形，一波行情；绿下还兰，下行横盘。白柱中红，预示上行；白柱中绿，预示下去。
例三、乘风K线
DRAWTEXTEX(1,0,0,0,'绿色弱势下跌'),COLOR005a00;
DRAWTEXTEX(1,0,100,0,'黄色弱势上升'),COLOR00CCFF;
DRAWTEXTEX(1,0,200,0,'粉红走强加仓'),COLORf00ff0;
DRAWTEXTEX(1,0,0,30,'红色上升满仓'),COLOR0000aa;
DRAWTEXTEX(1,0,100,30,'空心红反弹关注'),;
DRAWTEXTEX(1,0,200,30,'灰色强势调整'),COLORGRAY;
TYX3:=MA(REF(HHV((C+L+O+H)/4,30),1),3);
tyx4:=MA((C+L+O+H)/4,13);
TYX5:=EMA((C+L+O+H)/4,21);
{空心红}
STICKLINE(C<TYX5 AND C>O,H,L,0.1,1),COLORred;
STICKLINE(C<TYX5 AND C>O,C,O,8,1),COLORred;
{深绿}
STICKLINE(C<TYX5 AND C<O,h,l,0.1,0),COLOR009900;
STICKLINE(C<TYX5 AND C<O,C,O,8,0),COLOR005500;
STICKLINE(C<TYX5 AND C<O,C,O,6,0),COLOR005a00;
STICKLINE(C<TYX5 AND C<O,C,O,5,0),COLOR006600;
STICKLINE(C<TYX5 AND C<O,C,O,4,0),COLOR006b00;
STICKLINE(C<TYX5 AND C<O,C,O,3,0),COLOR007700;
STICKLINE(C<TYX5 AND C<O,C,O,1,0),COLOR007b00;
{蓝}
STICKLINE(C>TYX5 AND C<O,H,L,0.1,0),COLORFFAA22;
STICKLINE(C>TYX5 AND C<O,C,O,8,0 ),COLORFF7700;
STICKLINE(C>TYX5 AND C<O,C,O,6,0 ),COLORFF8811;
STICKLINE(C>TYX5 AND C<O,C,O,5,0 ),COLORFFAA22;
STICKLINE(C>TYX5 AND C<O,C,O,4,0 ),COLORFFBB33;
STICKLINE(C>TYX5 AND C<O,C,O,3 ,0 ),COLORFFDD44;
STICKLINE(C>TYX5 AND C<O,C,O,1 ,0 ),COLORFFFF55;
{黄}
STICKLINE(C>TYX5 AND C>O,H,L,0.1,0 ),COLOR00CCFF;
STICKLINE(C>TYX5 AND C>O,C,O,8,0 ),COLOR00AAFF;
STICKLINE(C>TYX5 AND C>O,C,O,6,0 ),COLOR00BBFF;
STICKLINE(C>TYX5 AND C>O,C,O,5,0 ),COLOR00CCFF;
STICKLINE(C>TYX5 AND C>O,C,O,4,0 ),COLOR00DDFF;
STICKLINE(C>TYX5 AND C>O,C,O,3,0 ),COLOR00EEFF;
STICKLINE(C>TYX5 AND C>O,C,O,1,0 ),COLOR00FFFF;
{粉红}
STICKLINE(C>TYX4 AND C>O,H,L,0.1,0),COLORAA00AA;
STICKLINE(C>TYX4 AND C>O,C,O,8,0 ),COLORFF11FF;
STICKLINE(C>TYX4 AND C>O,C,O,6,0 ),COLORFF33FF;
STICKLINE(C>TYX4 AND C>O,C,O,5,0 ),COLORFF44FF;
STICKLINE(C>TYX4 AND C>O,C,O,4,0 ),COLORFF55FF;
STICKLINE(C>TYX4 AND C>O,C,O,3,0 ),COLORFF66FF;
STICKLINE(C>TYX4 AND C>O,C,O,2,0 ),COLORFF77FF;
STICKLINE(C>TYX4 AND C>O,C,O,1,0 ),COLORFF88FF;
{亮灰}
STICKLINE(C>TYX4 AND C<O,H,L,0.1,0),COLORWHITE;
STICKLINE(C>TYX4 AND C<O,C,O,8,0),COLOR555555;
STICKLINE(C>TYX4 AND C<O,C,O,6,0),COLOR777777;
STICKLINE(C>TYX4 AND C<O,C,O,5,0),COLOR999999;
STICKLINE(C>TYX4 AND C<O,C,O,4,0),COLORAAAAAA;
STICKLINE(C>TYX4 AND C<O,C,O,3,0),COLORBBBBBB;
STICKLINE(C>TYX4 AND C<O,C,O,2,0),COLORcccccc;
STICKLINE(C>TYX4 AND C<O,C,O,1,0),COLORdddddd;
STICKLINE(C>TYX4 AND C<O,C,O,0.1,0),COLOReeeeee;
{深红}
STICKLINE(C>TYX3 AND C>O,h,l,0.5,0),COLOR0000dd;
STICKLINE(C>TYX3 AND C>O,C,O,8,0),COLOR000099;
STICKLINE(C>TYX3 AND C>O,C,O,6,0),COLOR0000aa;
STICKLINE(C>TYX3 AND C>O,C,O,5,0),COLOR0000bb;
STICKLINE(C>TYX3 AND C>O,C,O,4,0),COLOR0000cc;
STICKLINE(C>TYX3 AND C>O,C,O,3,0),COLOR0000dd;
STICKLINE(C>TYX3 AND C>O,C,O,2,0),COLOR0000ee;
STICKLINE(C>TYX3 AND C>O,C,O,1,0),COLOR0000ff;
{涨跌停K线}
STICKLINE(HIGH=LOW and CLOSE=OPEN and (CLOSE/REF(CLOSE,1))>1.048,HIGH,LOW,9,0) ,COLORRED;
STICKLINE(HIGH=LOW and CLOSE=OPEN and (REF(CLOSE,1)/CLOSE)>1.048,HIGH,LOW,9,0) ,COLOR00FF00;
{突破}
STICKLINE(REF(count(C<TYX3,5)=5,1) AND C>TYX3 AND C>O,C,O,2,0),COLOR00CCFF;
海面:MA(C,60),COLORFFFFFF,LINETHICK0;
乘风:MA(C,8),COLORYELLOW,LINETHICK0;
破浪:EMA(C,21),LINETHICK2,COLORMAGENTA;
PARTLINE(破浪>海面,海面),COLORFFFFFF;
PARTLINE(乘风>=破浪,乘风),COLORYELLOW,LINETHICK1;
PARTLINE(乘风>破浪 AND 乘风<=REF(乘风,1),乘风),COLORCYAN,LINETHICK1;
PARTLINE(破浪<=REF(破浪,1),破浪),COLORGREEN,LINETHICK2;
AA:=COUNT(CROSS(EMA(C,21),MA(C,8)),30)=1;
BB:=COUNT(CROSS(EMA(C,21),MA(C,60)),30)=1;
CC:=REF(BARSLAST(AA AND BB),1);
DD:=CC AND CROSS(MA(C,8),EMA(C,21));
DRAWTEXT(DD,(LOW * 0.99),'←乘风'),COLOR80FFFF;
主图中的柱线基本都是此类，也就是对K线进行修饰。此K线的用法已在主图中说明。
三、形态类
这里所说的形态只是侧重公式的表现形式而已，也就是以形体告诉我们股票的趋势信息。
例一：黑马黄牛
DRAWTEXTEX(1,1,1,1,'短线黑马小波段，中线黄牛大波澜；');
DRAWTEXTEX(1,1,1,150,'短线回头中线强，寻机低吸等反弹。');
MA1:=(C+O+H+L)/4;
MA8:=MA(MA1,8);
ZQSJ:=BARSLAST(CROSS(MA1,MA8))+1;
ZRSJ:=BARSLAST(CROSS(MA8,MA1))+1;
短线:IF(ZQSJ<=ZRSJ,REF(ZRSJ,1),0),COLOR0000FF,LINETHICK2;
黑马:IF(ZQSJ<=ZRSJ,0-REF(ZRSJ,1),0),COLOR0000FF,LINETHICK2;
XXSJ:=BARSLAST(CROSS(0.8,短线))+1;
休息:IF(短线=0,XXSJ,0),COLOR00FF00,POINTDOT,LINETHICK1;
RSV:=(CLOSE-LLV(LOW,34))/(HHV(HIGH,34)-LLV(LOW,34))*100;
K:=SMA(RSV,5,1);
D:=SMA(K,5,1);
J:=3*K-2*D;
中线:IF(J>K,J,0),COLOR00FFFF,LINETHICK2;
黄牛:IF(J>K,0-J,0),COLOR00FFFF,LINETHICK2;
强势:IF(J>K AND J>=50,50,IF(J>K,J,0)),COLORFF00FF,POINTDOT,LINETHICK0;
DXDD:=L=LLV(L,3) OR C=LLV(C,3);
回头:IF(DXDD AND COUNT(短线>0 AND 中线>=30,3)>=1,-30,0),COLORFFFFFF,LINETHICK2;
LC := REF(CLOSE,1);
RSI:=SMA(MAX(CLOSE-LC,0),2,1)/SMA(ABS(CLOSE-LC),2,1)*200-100;
RSI6:=SMA(MAX(CLOSE-LC,0),6,1)/SMA(ABS(CLOSE-LC),6,1)*200-100;
MA2:=MA(RSI,2);
太阳:IF(MA2>90 AND RSI6>50,1,0),COLOR0000FF,POINTDOT,LINETHICK0;
FILLRGN(中线>50 AND 中线>=REF(中线,1),50,中线),COLOR0000FF;
FILLRGN(中线>50 AND 中线<REF(中线,1),50,中线),COLOR00FF00;
FILLRGN(中线>100,100,中线),COLORFFFFFF;
DRAWICON(太阳,中线*1.3,2);
例二、会飞的鱼
AA:=REF(CLOSE,1);
BBB:=SMA(MAX(CLOSE-AA,0),21,1)/SMA(ABS(CLOSE-AA),21,1)*1000;
HHH:=BBB-LLV(BBB,27);
CCC:=LLV(BBB,27)-BBB;
QQ:(MA(HHH*1.5,2)*3+HHH*13)/16,COLOR445EAF,;
SS:(MA(CCC*1.5,2)*3+CCC*13)/16,COLORFF9D00;
QQ0:(MA(HHH*2,2)*3+HHH*13)/16,COLOR445EAF;
SS0:(MA(CCC*2,2)*3+CCC*13)/16,COLORFF9D00;
QQ1:(MA(HHH*2.5,2)*3+HHH*13)/16,COLOR445EAF;
SS1:(MA(CCC*2.5,2)*3+CCC*13)/16,COLORFF9D00;
QQ2:(MA(HHH*3,2)*3+HHH*13)/16,COLOR445EAF;
SS2:(MA(CCC*3,2)*3+CCC*13)/16,COLORFF9D00;
QQ3:(MA(HHH*3.5,2)*3+HHH*13)/16,COLOR445EAF;
SS3:(MA(CCC*3.5,2)*3+CCC*13)/16,COLORFF9D00;
QQ4:(MA(HHH*4,2)*3+HHH*13)/16,COLOR445EAF;
SS4:(MA(CCC*4,2)*3+CCC*13)/16,COLORFF9D00;
QQ5:(MA(HHH*4.5,2)*3+HHH*13)/16,COLOR445EAF;
SS5:(MA(CCC*4.5,2)*3+CCC*13)/16,COLORFF9D00;
QQ6:(MA(HHH*5,2)*3+HHH*13)/16,COLOR445EAF;
SS6:(MA(CCC*5,2)*3+CCC*13)/16,COLORFF9D00;
QQ7:(MA(HHH*5.5,2)*3+HHH*13)/16,COLOR445EAF;
SS7:(MA(CCC*5.5,2)*3+CCC*13)/16,COLORFF9D00;
SS8:(MA(CCC*6,2)*3+CCC*13)/16,COLORFF9D00;
GG:MA(HHH,3),LINETHICK1,COLORRED;
MM:MA(CCC,3),LINETHICK1,COLORGREEN;
WW:=IF(QQ<GG ,SS,MM);
EE:=IF(SS<MM ,GG,QQ);
EE1:=IF(SS<MM-4 ,GG-3,QQ-3);
WW1:=IF(QQ<GG-4 ,SS-3,MM-3);
STICKLINE(18,0,EE1-9,11,0),COLOR00509f;
STICKLINE(18,WW1+12,0,11,0),COLOR00999a;
V1:=EMA(CLOSE,60)-EMA(CLOSE,300);
V2:=EMA(V1,300);
V3:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
V4:=SMA(V3,2,1);
V5:=SMA(V4,2,1);
V6:=CLOSE/REF(CLOSE,3)>=1.1;
//强势描述
乖离13:=10-sma((C-ma(C,13))/ma(C,13),2,1)*10;
波段:=乖离13<10;
强弱a:=2.28*SMA((CLOSE-LLV(LOW,13))/(HHV(HIGH,13)-LLV(LOW,13))*58,5,1)-0*-10;
强弱b:=2.28*SMA((CLOSE-LLV(LOW,25))/(HHV(HIGH,25)-LLV(LOW,25))*58,5,1)-0*-10;
庄强c:=(强弱a>=ref(81,1))*强弱a;
牛庄:(强弱b>=ref(81,1))*强弱b;
STICKLINE(庄强c>ref(50,1),庄强c,ref(庄强c,1),6,1),COLORyellow,linethick2;
FILLRGN(波段,乖离13,28),COLORgreen;
这个公式利用趋势线以零轴为中心画了个对称图形，根据鱼形的收缩与张弛反映股票运行动态。
例三、十全十美
{金兰十全十美 飞狐版 多指标综合看盘}
DIFF:=EMA(CLOSE,3)-EMA(CLOSE,13);
DEA:=EMA(DIFF,5);
DRAWICON(DIFF>DEA,1,4);
DRAWICON(DIFF<DEA,1,5);
DRAWTEXT(ISLASTBAR=1,1,'.MACD'),COLORFFFFFF;
A1:=DIFF>DEA;
RSV1:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
K:=SMA(RSV1,3,1);
D:=SMA(K,3,1);
DRAWICON(K>D,2,4);
DRAWICON(K<D,2,5);
DRAWTEXT(ISLASTBAR=1,2,'.KDJ'),COLORFFFFFF;
A2:=K>D;
LC:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-LC,0),5,1))/(SMA(ABS(CLOSE-LC),5,1))*100;
RSI2:=(SMA(MAX(CLOSE-LC,0),13,1))/(SMA(ABS(CLOSE-LC),13,1))*100;
DRAWICON(RSI1>RSI2,3,4);
DRAWICON(RSI1<RSI2,3,5);
DRAWTEXT(ISLASTBAR=1,3,'.RSI'),COLORFFFFFF;
A3:=RSI1>RSI2;
RSV:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
LWR1:=SMA(RSV,3,1);
LWR2:=SMA(LWR1,3,1);
DRAWICON(LWR1>LWR2,4,4);
DRAWICON(LWR1<LWR2,4,5);
DRAWTEXT(ISLASTBAR=1,4,'.LW&R'),COLORFFFFFF;
A4:=LWR1>LWR2;
BBI:=(MA(CLOSE,3)+MA(CLOSE,5)+MA(CLOSE,8)+MA(CLOSE,13))/4;
DRAWICON(CLOSE>BBI,5,4);
DRAWICON(CLOSE<BBI,5,5);
DRAWTEXT(ISLASTBAR=1,5,'.BBI'),COLORFFFFFF;
A5:=CLOSE>BBI;
MTM:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(MTM,5),3)/EMA(EMA(ABS(MTM),5),3);
MMM:=100*EMA(EMA(MTM,13),8)/EMA(EMA(ABS(MTM),13),8);
DRAWICON(MMS>MMM,6,4);
DRAWICON(MMS<MMM,6,5);
DRAWTEXT(ISLASTBAR=1,6,'.ZLMM'),COLORFFFFFF;
A6:=MMS>MMM;
BIAS:=(C-MA(C,5))/MA(C,5);
DIF:=(BIAS-REF(BIAS,16));
DBCD:=SMA(DIF,76,1);
MM:=MA(DBCD,5);
DRAWICON(DBCD>MM ,7,4);
DRAWICON(DBCD<MM,7,5);
DRAWTEXT(ISLASTBAR=1,7,'.DBCD'),COLORFFFFFF;
A7:=DBCD>MM;
持股:3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),LINETHICK,COLORRED;
支撑:LLV(持股,3),LINETHICK,COLOR00FFFF;
下跌:MA(持股,12),COLOR6B8E23,LINETHICK;
转向:=CROSS(持股,下跌){ AND 下跌<30};
MA1:=MA(持股,5);
向下:=CROSS(MA1,持股) AND MA1>80;
DRAWICON(持股>下跌 ,8,4);
DRAWICON(持股<下跌,8,5);
DRAWTEXT(ISLASTBAR=1,8,'.CGZ'),COLORFFFFFF;
A8:=持股>下跌;
mtm:=c-ref(c,1);
ZLGJ:=100*ema(ema(mtm,8),8)/ema(ema(abs(mtm),8),8);
MAZL:=MA(ZLGJ,5);
DRAWICON(ZLGJ>MAZL,9,4);
DRAWICON(ZLGJ<MAZL,9,5);
A9:=ZLGJ>MAZL;
DRAWTEXT(ISLASTBAR=1,9,'.ZLGJ'),COLORFFFFFF;
PJJ:=DMA((HIGH+LOW+CLOSE*2)/4,0.9);
JJ:=REF(EMA(PJJ,3),1);
QJJ:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
XVL:=IF(CLOSE>OPEN,QJJ*(HIGH-LOW),IF(CLOSE<OPEN,QJJ*(HIGH-OPEN+CLOSE-LOW),VOL/2))+IF(CLOSE>OPEN,0-QJJ*(HIGH-CLOSE+OPEN-LOW),IF(CLOSE<OPEN,0-QJJ*(HIGH-LOW),0-VOL/2));
HSL:=(XVL/20)/1.15;
攻击流量:=((HSL*0.55+(REF(HSL,1)*0.33))+(REF(HSL,2)*0.22));
GJJ:=EMA(攻击流量,8);
LLJX:=EMA(攻击流量,3);
资金流量:LLJX,LINETHICK0,COLOR0000FF;
DRAWICON(资金流量>0,10,4);
DRAWICON(资金流量<0,10,5);
A10:=资金流量>0;
DRAWTEXT(ISLASTBAR=1,10,'.ZJL'),COLORFFFFFF;
指导线:(A1+A2+A3+A4+A5+A6+A7+A8+A9+A10),linethick2,COLORFFFF00;
选股:IF(指导线 >6 ,1,0),linethick3,ColorFF00FF;
这是将若干个系统公式集中在一起的，使用方法一目了然。
最后大家鉴赏一下本区的一个很有特色的形态公式：中国长城：
说明：上文内容没有一一印证，只是留存。
联系客服
