FLASH网游通过XMLSocket与VB后台通信教程

转自闪吧论坛 陈策（作者）

前段时间用Flash做了个网游的Demo，通讯用的是Socket。曾承诺写个教程，现在有空就把它写写吧。
先从FLASH说起。我要达到的效果是点击地面，人物就走到点击的地点。思路：一个鼠标监听器监听鼠标的点击事件，把X座标和Y座标传到角色，做为角色的目的地。角色每一帧都向这个目的地移动一点点。
role_mc为场景里的一个MovieClip

1. 
   
2. role_mc.x = role_mc._x;
   
3. role_mc.y = role_mc._y;
   
4. var mouseListener:Object = new Object();
   
5. mouseListener.onMouseDown = function() {
   
6. moveRole(role_mc, _xmouse, _ymouse);
   
7. };
   
8. Mouse.addListener(mouseListener);
   
9. function moveRole(role:MovieClip, x:Number, y:Number) {
   
10. role.x = x;
    
11. role.y = y;
    
12. role.onEnterFrame = function() {
    
13.   if (this.x != this._x) {
    
14.    this._x += this.x-this._x>0 ? 1 : -1;
    
15.   }
    
16.   if (this.y != this._y) {
    
17.    this._y += this.y-this._y>0 ? 1 : -1;
    
18.   }
    
19.   if (this.x == this._x && this.y == this._y) {
    
20.    delete this.onEnterFrame;
    
21.   }
    
22. };
    
23. }

复制代码

试一下效果，发现角色会斜45度角移动到与目的地垂直或者水平后再垂直或水平运动。这是move函数里的算法没写好。我们现在来想想我想需要的是怎么样的移动。
[1.gif]
如图，角色在A点，要移动到B点去，方向就是AB。C点是下一帧角色将会出现的点，那向量AC就相当于角色的速度。将向量AC分解到两轴就得到x方向上的向量AE和y方向上的向量AD，这就是角色在这帧里需要移动的xy值了。角色的速度是已知的，要得到两个分解的向量，就只需要知道角度就行了。角度也可以根据A点和B点得到。我把角色面向右边时定为0度，则向上时为-90度，向下为90度，向左为180度。之所以这么定是为了计算方便。如Math.atan2(role_mc.y-role_mc._y, role_mc.x-role_mc._x)就可以直接到得角色面向的方向了（注意，Math.atan2得到的是以弧度为单位的数，不是角度）。所以把AS改写成：

1. role_mc.x = role_mc._x;
   
2. role_mc.y = role_mc._y;
   
3. role_mc.speed = 5;
   
4. role_mc.angle = 0;
   
5. var mouseListener:Object = new Object();
   
6. mouseListener.onMouseDown = function() {
   
7. moveRole(role_mc, _xmouse, _ymouse);
   
8. };
   
9. Mouse.addListener(mouseListener);
   
10. function moveRole(role:MovieClip, x:Number, y:Number) {
    
11. role.x = x;
    
12. role.y = y;
    
13. role.angle = Math.atan2(role.y-role._y, role.x-role._x);
    
14. role.onEnterFrame = function() {
    
15.   if (this.x != this._x) {
    
16.    this._x += Math.abs(this.x-this._x)>Math.abs(this.speed*Math.cos(this.angle)) ? this.speed*Math.cos(this.angle) : this.x-this._x; //当角色和目的地的距离小于角色的速度时，就不能再以速度计算出的位移，而直接移动到目的地，Y方向同理
    
17.   }
    
18.   if (this.y != this._y) {
    
19.    this._y += Math.abs(this.y-this._y)>Math.abs(this.speed*Math.sin(this.angle)) ? this.speed*Math.sin(this.angle) : this.y-this._y;
    
20.   }
    
21.   if (this.x == this._x && this.y == this._y) {
    
22.    delete this.onEnterFrame;
    
23.   }
    
24. };
    
25. }

复制代码

移动看起来应该没什么大问题了。现在来做人物。把自己画的人物，或者是从游戏里抓图弄出来的人物处理好，我有两张从RO里弄出来的图。
[role.png][head.png]
将两张图导入到FLASH的role_mc里。因为我是把身体和头部所有方向都做成一张图，所以要用遮照来只显示需要的那个。将第一帧做成第一个方向的站立，给帧起名stand_1，加AS：stop()；后边若干帧做成行走的动画，给帧起名run_1，加AS：play()；在行走动画的后边加上一帧空白关健帧，加AS：gotoAndPlay("run_1")。这就完成了一个方向。在这一段后边加上其他几个方向。我做的是方向1为向下，2为左下，3为左，4为左上，5为上。其他三个方向可以之后用AS将234方向做水平翻转达到。也许我说得不是很明白，看我的这个文件（teach1.fla）就知道了。做好这一步之后，就可以在moveRole函数里加些东西，让角色做出相应的动作。我们先画个图来看一看角色的angle值分别代表角色面向哪个方向。见下图
[2.gif]
图中的红线就是每个方向的分隔线，把角度也列出来了，用弧度为单位是为了方便以后的计算。把AS也修改了一下就达到行走效果了。

1. 
   
2. role_mc.x = role_mc._x;
   
3. role_mc.y = role_mc._y;
   
4. role_mc.speed = 5;
   
5. role_mc.angle = 0;
   
6. var mouseListener:Object = new Object();
   
7. mouseListener.onMouseDown = function() {
   
8. moveRole(role_mc, _xmouse, _ymouse);
   
9. };
   
10. Mouse.addListener(mouseListener);
    
11. function moveRole(role:MovieClip, x:Number, y:Number) {
    
12. role.x = x;
    
13. role.y = y;
    
14. role.angle = Math.atan2(role.y-role._y, role.x-role._x);
    
15. role.dire = 1+Math.round((role.angle+Math.PI)/(Math.PI/4)); //把角色面向的角度的值从-Math.PI到Math.PI的范围变为1到8的自然数，分别代码八个方向
    
16. role.dire = role.dire>6 ? role.dire-6 : role.dire+2; //把八个方向处理一下，和图上代表的方向符合
    
17. if (role.dire>5) {
    
18.   //如果方向为789中的一个，就水平翻转MC
    
19.   role.dire = role.dire == 6 ? 4 : role.dire == 7 ? 3 : 2; //方向6对应方向4，7对应3，8对应2
    
20.   role._xscale = -100;
    
21. } else {
    
22.   role._xscale = 100;
    
23. }
    
24. role.gotoAndPlay("run_"+role.dire);
    
25. role.onEnterFrame = function() {
    
26.   if (this.x != this._x) {
    
27.    this._x += Math.abs(this.x-this._x)>Math.abs(this.speed*Math.cos(this.angle)) ? this.speed*Math.cos(this.angle) : this.x-this._x;
    
28.   }
    
29.   if (this.y != this._y) {
    
30.    this._y += Math.abs(this.y-this._y)>Math.abs(this.speed*Math.sin(this.angle)) ? this.speed*Math.sin(this.angle) : this.y-this._y;
    
31.   }
    
32.   if (this.x == this._x && this.y == this._y) {
    
33.    delete this.onEnterFrame;
    
34.    this.gotoAndStop("stand_"+this.dire);
    
35.   }
    
36. };
    
37. }

复制代码

大体样子已经出来了。现在我们来想想，其他的玩家要怎么办？当收到服务器有新玩家登陆这里的时候，FLASH要添加一个新的角色在画面上。我们可以做一个创造角色的函数，收到有新人登陆时就添加一个。而自己登陆的时候也可以用这个函数来创建自己。其他玩家移动，也是从服务器收到是谁要移动到哪的信息，FLASH只要调用moveRole函数就可以了。现在先做一个创建角色的函数。role_mc不需要再放在场景里，在库里给他一个链接名role，就可以方便用attachMovie命令调用了。

1. 
   
2. role_mc.x = role_mc._x;
   
3. role_mc.y = role_mc._y;
   
4. role_mc.speed = 5;
   
5. role_mc.angle = 0;
   
6. var mouseListener:Object = new Object();
   
7. mouseListener.onMouseDown = function() {
   
8. moveRole(role_mc, _xmouse, _ymouse);
   
9. };
   
10. Mouse.addListener(mouseListener);
    
11. function moveRole(role:MovieClip, x:Number, y:Number) {
    
12. role.x = x;
    
13. role.y = y;
    
14. role.angle = Math.atan2(role.y-role._y, role.x-role._x);
    
15. role.dire = 1+Math.round((role.angle+Math.PI)/(Math.PI/4)); //把角色面向的角度的值从-Math.PI到Math.PI的范围变为1到8的自然数，分别代码八个方向
    
16. role.dire = role.dire>6 ? role.dire-6 : role.dire+2; //把八个方向处理一下，和图上代表的方向符合
    
17. if (role.dire>5) {
    
18.   //如果方向为789中的一个，就水平翻转MC
    
19.   role.dire = role.dire == 6 ? 4 : role.dire == 7 ? 3 : 2; //方向6对应方向4，7对应3，8对应2
    
20.   role._xscale = -100;
    
21. } else {
    
22.   role._xscale = 100;
    
23. }
    
24. role.gotoAndPlay("run_"+role.dire);
    
25. role.onEnterFrame = function() {
    
26.   if (this.x != this._x) {
    
27.    this._x += Math.abs(this.x-this._x)>Math.abs(this.speed*Math.cos(this.angle)) ? this.speed*Math.cos(this.angle) : this.x-this._x;
    
28.   }
    
29.   if (this.y != this._y) {
    
30.    this._y += Math.abs(this.y-this._y)>Math.abs(this.speed*Math.sin(this.angle)) ? this.speed*Math.sin(this.angle) : this.y-this._y;
    
31.   }
    
32.   if (this.x == this._x && this.y == this._y) {
    
33.    delete this.onEnterFrame;
    
34.    this.gotoAndStop("stand_"+this.dire);
    
35.   }
    
36. };
    
37. }
    
38. 大体样子已经出来了。现在我们来想想，其他的玩家要怎么办？当收到服务器有新玩家登陆这里的时候，FLASH要添加一个新的角色在画面上。我们可以做一个创造角色的函数，收到有新人登陆时就添加一个。而自己登陆的时候也可以用这个函数来创建自己。其他玩家移动，也是从服务器收到是谁要移动到哪的信息，FLASH只要调用moveRole函数就可以了。现在先做一个创建角色的函数。role_mc不需要再放在场景里，在库里给他一个链接名role，就可以方便用attachMovie命令调用了。
    
39. //创建鼠标监听器
    
40. var mouseListener:Object = new Object();
    
41. mouseListener.onMouseDown = function() {
    
42. for (var i = 0; i<allRoles.length; i++) {
    
43.   if (allRoles[i].ctrl) {
    
44.    moveRole(allRoles[i], _xmouse, _ymouse);
    
45.    break;
    
46.   }
    
47. }
    
48. };
    
49. Mouse.addListener(mouseListener);
    
50. //创建角色
    
51. var allRoles:Array = new Array();
    
52. allRoles[allRoles.length] = createRole(Math.random(), true, 5, Stage.width/2, Stage.height/2);
    
53. function createRole() {
    
54. var roleObj:MovieClip = this.attachMovie("role", "role_mc", this.getNextHighestDepth());
    
55. roleObj.id = arguments[0]; //区别每一个角色的ID，可以从数据库中得到值。在这个教程里就直接用一个随机数代替
    
56. roleObj.ctrl = arguments[1]; //标识该角色是否为由玩家控制的角色
    
57. roleObj.speed = arguments[2];
    
58. roleObj._x = arguments[3];
    
59. roleObj._y = arguments[4];
    
60. roleObj.x = roleObj._x;
    
61. roleObj.y = roleObj._y;
    
62. return roleObj;
    
63. }
    
64. //角色移动
    
65. function moveRole(role:MovieClip, x:Number, y:Number) {
    
66. role.x = x;
    
67. role.y = y;
    
68. role.angle = Math.atan2(role.y-role._y, role.x-role._x);
    
69. role.dire = 1+Math.round((role.angle+Math.PI)/(Math.PI/4));
    
70. role.dire = role.dire>6 ? role.dire-6 : role.dire+2;
    
71. if (role.dire>5) {
    
72.   role.dire = role.dire == 6 ? 4 : role.dire == 7 ? 3 : 2;
    
73.   role._xscale = -100;
    
74. } else {
    
75.   role._xscale = 100;
    
76. }
    
77. role.gotoAndPlay("run_"+role.dire);
    
78. role.onEnterFrame = function() {
    
79.   if (this.x != this._x) {
    
80.    this._x += Math.abs(this.x-this._x)>Math.abs(this.speed*Math.cos(this.angle)) ? this.speed*Math.cos(this.angle) : this.x-this._x;
    
81.   }
    
82.   if (this.y != this._y) {
    
83.    this._y += Math.abs(this.y-this._y)>Math.abs(this.speed*Math.sin(this.angle)) ? this.speed*Math.sin(this.angle) : this.y-this._y;
    
84.   }
    
85.   if (this.x == this._x && this.y == this._y) {
    
86.    delete this.onEnterFrame;
    
87.    this.gotoAndStop("stand_"+this.dire);
    
88.   }
    
89. };
    
90. }

复制代码

[ 本帖最后由 陈策 于 2007-6-20 17:03 编辑 ]

1.gif (3.71 KB)

1.gif

role.png (63.94 KB)

role.png

head.png (27.74 KB)

head.png

2.gif (12.98 KB)

2.gif

teach1.fla (143.5 KB)

图和相关文字不能放在一起-_- 大家麻烦点，上下对着看吧。

接下来是后台服务器的制作。我用的是Microsoft Visual Studio .NET 2003。语言为VB。
首先建一个空项目，命名为server（图3）。在这个项目的“解决方案资源管理器”上右击项目，选择“添加(D)”-“添加新项(W)”，添加一个类，命名为server.vb（图4）。在server.vb里写上socket的代码。我是从微软件的网站上的例子上修改来的，也没什么可说的。

1. 
   
2. Imports System.Net
   
3. Imports System.Net.Sockets
   
4. Namespace ibaiy
   
5.     Public Class Server
   
6.         Private lisenSocket As Socket
   
7.         Private allRoles As New Hashtable 
   
8. Private rolesPosition As New Hashtable
   
9. '在这个例子中我不打算用数据库了，所以建一个hashtable来存在线用户的资料。如果要存入数据库，只需要加上登陆后验证用户名密码，读数据库资料，再存到这个hashtable里。用户做了操作时再把hashtable里的数据处理后再写入数据库就可以了。这里的操作不难，但比较麻烦，所以我偷下懒
   
10.         '启动服务的主函数
    
11.         Public Sub startServer(ByVal port As Integer)
    
12.             lisenSocket = New Socket(AddressFamily.InterNetwork, SocketType.Stream, ProtocolType.Tcp)
    
13.             Dim ipen As IPHostEntry = Dns.Resolve(Dns.GetHostName)
    
14.             Dim endpoint = New IPEndPoint(ipen.AddressList(0).Any, port)
    
15.             lisenSocket.Bind(endpoint)
    
16.             lisenSocket.Listen(1000)
    
17.             lisenSocket.BeginAccept(AddressOf Me.Listen_Callback, lisenSocket)
    
18.         End Sub
    
19.         Public Sub Listen_Callback(ByVal result As IAsyncResult)
    
20.             Dim s As Socket = CType(result.AsyncState, Socket)
    
21.             Dim so2 As New StateObject
    
22.             so2.workSocket = s.EndAccept(result)
    
23.             so2.workSocket.BeginReceive(so2.buffer, 0, so2.buffer.Length, 0, AddressOf Me.Read_Callback, so2)
    
24.             s.BeginAccept(AddressOf Me.Listen_Callback, s)
    
25.         End Sub
    
26.         Public Sub Read_Callback(ByVal result As IAsyncResult)
    
27.             Dim so As StateObject = CType(result.AsyncState, StateObject)
    
28.             so.len = so.workSocket.EndReceive(result)
    
29.             opMsg(so)
    
30.             so.buffer.Clear(so.buffer, 0, so.buffer.Length)
    
31.             Try
    
32.                 so.workSocket.BeginReceive(so.buffer, 0, so.buffer.Length, SocketFlags.None, AddressOf Me.Read_Callback, so)
    
33.             Catch
    
34.             End Try
    
35.         End Sub
    
36. '这个函数就是处理服务器收到客户端消息的处理函数，一会详细说明
    
37.         Public Sub opMsg(ByVal so As StateObject)
    
38.         End Sub
    
39.     End Class
    
40. End Namespace

复制代码

在server项目里像添加server.vb一样再添加一个StateObject.vb。这是为每个联接的SOCKET一定的buffer，索性做了一个新的类。写以下代码：

1. 
   
2. Imports System.Net.Sockets
   
3. Namespace ibaiy
   
4.     Public Class StateObject
   
5.         Public buffer(1024) As Byte
   
6.         Public workSocket As Socket
   
7.         Public len As Integer
   
8.     End Class
   
9. End Namespace

复制代码

3.gif (14.77 KB)

4.gif (13.5 KB)

我们要先想好客户端和服务器端有什么资料要通讯的，定好通讯的格式。我是这样设计的：通讯的资料我就不加密了，格式是01u=aa&xxxx 。前两位是代表了是做什么。u=aa是用户aa 做的操作。xxxx是操作的内容。
00 由服务器提供给客户端(简称S2C,下同)，返回当前在线的所有用户。如：00u=a&x=0&y=0&u=b&x=54&y=78
01 C2S 用户登陆 如：01u=a
   S2C 告诉其他在线用户有新用户登陆 如：01u=a
02 C2S 用户移动 如：02u=a&x=100&y=50
   S2C 告诉其他在线用户某个用户在移动 如：02u=a&x=100&y=50
03 C2S 用户下线 如：03u=a
   S2C 告诉其他在线用户某个用户下线了 如：03u=a
04 C2S 用户发言 如：04u=a&内容
   S2C 告诉其他在线用户某个用户的发言 如：04u=a&内容
这里要说一下用户下线，用户下线是由用户在客户端点击“下线”完成，也可以是点击关闭FLASH的窗口完成。如果是点“下线”，那就由FLASH发送03过来就可以了。如果是点击关闭窗口的话，那只能由服务器端判断。当收到客户端发送的数据长度为零时，就可以判断客户端下线了。opMsg函数如下：

1. 
   
2.         '处理收到的数据
   
3.         Public Sub opMsg(ByVal so As StateObject)
   
4.             Dim username As String
   
5.             Dim sendmsg As String
   
6.             Dim keys As IDictionaryEnumerator
   
7.             '如果发送消息长度为0，断开客户端
   
8.             If so.len < 1 Then
   
9.                 keys = Me.allRoles.Values().GetEnumerator
   
10.                 While keys.MoveNext
    
11.                     If keys.Current.Equals(so.workSocket) Then
    
12.                         username = CType(keys.Key, String)
    
13.                     End If
    
14.                 End While
    
15.                 so.workSocket.Close()
    
16.                 sendmsg = "03u=" + username + Chr(0)
    
17.                 keys.Reset()
    
18.                 While keys.MoveNext
    
19.                     If Not keys.Current.Equals(so.workSocket) Then
    
20.                         Me.send(keys.Key, sendmsg)
    
21.                     End If
    
22.                 End While
    
23.                 Me.allRoles.Remove(username)
    
24.                 Me.rolesPosition.Remove(username)
    
25.                 Exit Sub
    
26.             End If
    
27.             Dim msg As String = System.Text.Encoding.UTF8.GetString(so.buffer, 0, so.len - 1)
    
28.             Dim msgtype As String = Left(msg, 2)
    
29.             Select Case msgtype
    
30.                 Case "01"   '登陆
    
31.                     Dim newMsg As String = "00"
    
32.                     Dim isIn As Boolean = False
    
33.                     username = Right(msg, msg.Length - 4)
    
34.                     keys = Me.allRoles.Keys().GetEnumerator
    
35.                     While keys.MoveNext
    
36.                         If keys.Key <> username Then
    
37.                             If newMsg <> "00" Then
    
38.                                 newMsg += "&"
    
39.                             End If
    
40.                             newMsg += "u=" + keys.Key + Me.rolesPosition.Item(keys.Key)
    
41.                         Else
    
42.                             isIn = True
    
43.                         End If
    
44.                     End While
    
45.                     newMsg += Chr(0)    '考虑到FLASH里接收SOCKET是用XMLSocket，每个 XML 消息都是一个完整的 XML 文档，以一个零 (0) 字节结束。所以以chr(0)结束。
    
46.                     If Not (isIn) Then
    
47.                         Me.allRoles.Add(username, so.workSocket)
    
48.                         Me.rolesPosition.Add(username, "&x=275&y=200") '这里我给角色初位置是（275，200），正好是在FLASH场景的中心。
    
49.                         sendmsg = msgtype + "u=" + username + "&x=275&y=200" + Chr(0)
    
50.                         keys = Me.allRoles.Keys().GetEnumerator
    
51.                         While keys.MoveNext
    
52.                             If keys.Key = username Then
    
53.                                 Me.send(keys.Current, newMsg)
    
54.                             Else
    
55.                                 Me.send(keys.Current, sendmsg)
    
56.                             End If
    
57.                         End While
    
58.                     End If
    
59.                 Case "02"   '移动
    
60.                     username = Right(msg.Split("&")(0), msg.Split("&")(0).Length - 4)
    
61.                     If CType(Me.allRoles.Item(username), Socket).Equals(so.workSocket) Then
    
62.                         Dim xy As String = Right(msg, msg.Length - msg.Split("&")(0).Length)
    
63.                         Me.rolesPosition.Item(username) = xy
    
64.                         keys = Me.allRoles.Keys().GetEnumerator
    
65.                         While keys.MoveNext
    
66.                             If keys.Key <> username Then
    
67.                                 Me.send(keys.Current, msg + Chr(0))
    
68.                             End If
    
69.                         End While
    
70.                     End If
    
71.                 Case "03"   '下线
    
72.                     username = Right(msg, msg.Length - 4)
    
73.                     If CType(Me.allRoles.Item(username), Socket).Equals(so.workSocket) Then
    
74.                         keys = Me.allRoles.Values().GetEnumerator
    
75.                         While keys.MoveNext
    
76.                             If Not keys.Current.Equals(so.workSocket) Then
    
77.                                 Me.send(keys.Key, msg + Chr(0))
    
78.                             End If
    
79.                         End While
    
80.                         Me.allRoles.Remove(username)
    
81.                         Me.rolesPosition.Remove(username)
    
82.                         so.workSocket.Close()
    
83.                     End If
    
84.                 Case "04"   '聊天
    
85.                     username = Right(msg.Split("&")(0), msg.Split("&")(0).Length - 4)
    
86.                     If CType(Me.allRoles.Item(username), Socket).Equals(so.workSocket) Then
    
87.                         keys = Me.allRoles.Keys().GetEnumerator
    
88.                         While keys.MoveNext
    
89.                             Me.send(keys.Current, msg + Chr(0))
    
90.                         End While
    
91.                     End If
    
92.             End Select
    
93.         End Sub

复制代码

要注意的是，发送的消息要以chr(0)结尾，这样FLASH才知道这是消息的尾，否则FLASH会以为还没完，还在等后边不存在的数据传过来。因为我懒，所以不打算在这个教程里做与数据库相关联的例子，如果要加的话，就在这个函数里的case里加就可以了。正确的做法应该是把每个case里的代码整理成一个个的功能块，方便以后调用。我懒-_-
还要写一个从服务器发消息给客户端的函数：

1. 
   
2.         '向一个用户主动发信息
   
3.         Public Sub send(ByVal user As Object, ByVal msg As String)
   
4.             Dim sends As Socket
   
5.             sends = CType(allRoles.Item(user), Socket)
   
6.             Dim buffer() As Byte
   
7.             buffer = System.Text.Encoding.UTF8.GetBytes(msg)
   
8.             sends.BeginSend(buffer, 0, buffer.Length, SocketFlags.None, AddressOf Me.Send_Callback, sends)
   
9.         End Sub
   
10.         Public Sub Send_Callback(ByVal result As IAsyncResult)
    
11.             CType(result.AsyncState, Socket).EndSend(result)
    
12.         End Sub

复制代码

做好这个DLL文件了，做一个面板吧。其时这是在开始写server.vb的时候就应该做的事，刚才给忘了。现在加上。在右边的“解决方案资源管理器”里右击“解决方案”,选择“添加(D)”“添加新项目(N)...”“visual Basic 项目”“Windows 应用程序”，命名为rpg。如图5[5.gif]。在“解决方案资源管理器”里右击“rpg”，选择“项目依赖项”，在弹出窗口里勾选server（刚才做的那个文件的名字）。在“rpg”下一行的“引用”上右击，选择“添加引用”，“浏览”找到用server.vb(server文件夹下有个bin文件夹，如果里边没有，你就先按F5调试生成它)生成的server.dll文件，选中之。在rpg上右击，再选择“设为启动项目(A)”。在rpg的面板上添加一个按钮，加上以下程序：

1. 
   
2.     Private isStarted As Boolean
   
3.     Private rpgServer As server.ibaiy.Server
   
4.     Private Sub ServerForm_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
   
5.         Me.isStarted = False
   
6.     End Sub
   
7.     Private Sub Button_start_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button_start.Click
   
8.         If Not Me.isStarted Then
   
9.             Me.rpgServer = New server.ibaiy.Server
   
10.             Me.rpgServer.startServer(9999)
    
11.             Me.isStarted = True
    
12.         End If
    
13.     End Sub

复制代码

现在可以调试一下VB的程序了。我做了一个简单的FLASH来测试的。这个FLASH就不说明怎么做了。我在下边有提供。[socket.swf]，有兴趣的朋友可以自己看看。使用方法：服务器启动后，点击socket.swf上边的connect按钮，成功或者失败都会在中间显示出来。如果成功，就可以在下边输入要传输入的文字，格式就是上边我们定义好的“01u=a”之类的，当收到服务器传过来的文字也会在中间显示出来。可以开几个看看效果。

5.gif (15.09 KB)

socket.swf (42.01 KB)

接下来是在有人物的FLASH里加入与服务器通讯的功能了。我在FLASH的AS里加入XMLSocket的代码：

1. 
   
2. //数据链接
   
3. var conects:String = "127.0.0.1";
   
4. var socket:XMLSocket = new XMLSocket();
   
5. socket.connect(conects, 9999);
   
6. this.socket.onData = function(str:String) {
   
7. var type:String = str.substr(0, 2);
   
8. var tmparr:Array = str.substr(2).split("&");
   
9. //所有在线角色和位置
   
10. if (type == "00") {
    
11.   if (tmparr.length>1) {
    
12.    for (var i:Number = 0; i<tmparr.length; i += 3) {
    
13.     tmpName = tmparr[i].split("=");
    
14.     tmpx = tmparr[(i+1)].split("=");
    
15.     tmpy = tmparr[(i+2)].split("=");
    
16.     allRoles[allRoles.length] = createRole(tmpName[1], false, 5, Number(tmpx[1]), Number(tmpy[1]));
    
17.    }
    
18.   }
    
19. }
    
20. //有新用户登陆
    
21. if (type == "01") {
    
22.   tmpName = tmparr[0].split("=");
    
23.   allRoles[allRoles.length] = createRole(tmpName[1], false, 5, Stage.width/2, Stage.height/2);
    
24. }
    
25. //有用户移动
    
26. if (type == "02") {
    
27.   tmpName = tmparr[0].split("=");
    
28.   tmpx = tmparr[1].split("=");
    
29.   tmpy = tmparr[2].split("=");
    
30.   for (var i = 0; i<allRoles.length; i++) {
    
31.    if (allRoles[i].id == tmpName[1]) {
    
32.     moveRole(allRoles[i], Number(tmpx[1]), Number(tmpy[1]));
    
33.     break;
    
34.    }
    
35.   }
    
36. }
    
37. //用户下线
    
38. if (type == "03") {
    
39.   tmpName = tmparr[0].split("=");
    
40.   for (var i = 0; i<allRoles.length; i++) {
    
41.    if (allRoles[i].id == tmpName[1]) {
    
42.     trace(allRoles[i])
    
43.     removeMovieClip(allRoles[i]);
    
44.     allRoles[i].splice(i, 1);
    
45.     break;
    
46.    }
    
47.   }
    
48. }
    
49. };

复制代码

当然，原来的代码里还要加上一些东西，比如在创造角色的时候，要判断是否是自己控制的角色，是的话就要告诉服务器我登陆了。比如在鼠标点击的时候，也要告诉服务器我移动了。下边我把完整的AS代码再贴一遍。

1. //数据链接
   
2. var conects:String = "127.0.0.1";
   
3. var socket:XMLSocket = new XMLSocket();
   
4. socket.connect(conects, 9999);
   
5. this.socket.onData = function(str:String) {
   
6. var type:String = str.substr(0, 2);
   
7. var tmparr:Array = str.substr(2).split("&");
   
8. if (type == "00") {
   
9.   if (tmparr.length>1) {
   
10.    for (var i:Number = 0; i<tmparr.length; i += 3) {
    
11.     tmpName = tmparr[i].split("=");
    
12.     tmpx = tmparr[(i+1)].split("=");
    
13.     tmpy = tmparr[(i+2)].split("=");
    
14.     allRoles[allRoles.length] = createRole(tmpName[1], false, 5, Number(tmpx[1]), Number(tmpy[1]));
    
15.    }
    
16.   }
    
17. }
    
18. if (type == "01") {
    
19.   tmpName = tmparr[0].split("=");
    
20.   allRoles[allRoles.length] = createRole(tmpName[1], false, 5, Stage.width/2, Stage.height/2);
    
21. }
    
22. if (type == "02") {
    
23.   tmpName = tmparr[0].split("=");
    
24.   tmpx = tmparr[1].split("=");
    
25.   tmpy = tmparr[2].split("=");
    
26.   for (var i = 0; i<allRoles.length; i++) {
    
27.    if (allRoles[i].id == tmpName[1]) {
    
28.     moveRole(allRoles[i], Number(tmpx[1]), Number(tmpy[1]));
    
29.     break;
    
30.    }
    
31.   }
    
32. }
    
33. if (type == "03") {
    
34.   tmpName = tmparr[0].split("=");
    
35.   for (var i = 0; i<allRoles.length; i++) {
    
36.    if (allRoles[i].id == tmpName[1]) {
    
37.     trace(allRoles[i]);
    
38.     removeMovieClip(allRoles[i]);
    
39.     allRoles[i].splice(i, 1);
    
40.     break;
    
41.    }
    
42.   }
    
43. }
    
44. };
    
45. //创建鼠标监听器
    
46. var mouseListener:Object = new Object();
    
47. mouseListener.onMouseDown = function() {
    
48. for (var i = 0; i<allRoles.length; i++) {
    
49.   if (allRoles[i].ctrl) {
    
50.    moveRole(allRoles[i], _xmouse, _ymouse);
    
51.    socket.send("02u="+allRoles[i].id+"&x="+_xmouse+"&y="+_ymouse);
    
52.    break;
    
53.   }
    
54. }
    
55. };
    
56. Mouse.addListener(mouseListener);
    
57. //创建角色
    
58. var allRoles:Array = new Array();
    
59. allRoles[allRoles.length] = createRole(Math.random(), true, 5, Stage.width/2, Stage.height/2);
    
60. function createRole() {
    
61. var roleObj:MovieClip = this.attachMovie("role", "role"+allRoles.length+"_mc", this.getNextHighestDepth());
    
62. roleObj.id = arguments[0];
    
63. roleObj.ctrl = arguments[1];
    
64. roleObj.speed = arguments[2];
    
65. roleObj._x = arguments[3];
    
66. roleObj._y = arguments[4];
    
67. roleObj.x = roleObj._x;
    
68. roleObj.y = roleObj._y;
    
69. //如果是创造了玩家自己，就要向告诉服务器“我登陆了”
    
70. if (arguments[1]) {
    
71.   socket.send("01u="+arguments[0]);
    
72. }
    
73. return roleObj;
    
74. }
    
75. //角色移动
    
76. function moveRole(role:MovieClip, x:Number, y:Number) {
    
77. role.x = x;
    
78. role.y = y;
    
79. role.angle = Math.atan2(role.y-role._y, role.x-role._x);
    
80. role.dire = 1+Math.round((role.angle+Math.PI)/(Math.PI/4));
    
81. role.dire = role.dire>6 ? role.dire-6 : role.dire+2;
    
82. if (role.dire>5) {
    
83.   role.dire = role.dire == 6 ? 4 : role.dire == 7 ? 3 : 2;
    
84.   role._xscale = -100;
    
85. } else {
    
86.   role._xscale = 100;
    
87. }
    
88. role.gotoAndPlay("run_"+role.dire);
    
89. role.sta;
    
90. role.onEnterFrame = function() {
    
91.   if (this.x != this._x) {
    
92.    this._x += Math.abs(this.x-this._x)>Math.abs(this.speed*Math.cos(this.angle)) ? this.speed*Math.cos(this.angle) : this.x-this._x;
    
93.   }
    
94.   if (this.y != this._y) {
    
95.    this._y += Math.abs(this.y-this._y)>Math.abs(this.speed*Math.sin(this.angle)) ? this.speed*Math.sin(this.angle) : this.y-this._y;
    
96.   }
    
97.   if (this.x == this._x && this.y == this._y) {
    
98.    delete this.onEnterFrame;
    
99.    this.gotoAndStop("stand_"+this.dire);
    
100.   }
     
101. };
     
102. }

复制代码

以下是做好的所有文件，包括FLASH源文件和VB源文件。

game.rar (183.74 KB)

因为后台是用VS2003写的，所以在没有装VS的电脑上好象运行不了服务器。这个教程写了好几天，终于完成了。原来还想把聊天功能，换头发功能都做上去的，懒了。都是上班时候偷着做的。改天有时间想做个完整的游戏出来玩玩：D:lol

:'( 没人顶，自己支持一下。谁知道哪有支持ASP.net和Socket的空间呀？我的空间上放FLASH网游不行:Q ，时断时续的。
http://www.ibaiy.com/rpg.aspx

我在教程里做的服务器是一个软件，要在服务器安装才可以，但后来我把server.dll文件做成.net页面下的一个插件，在aspx的页面就可以启动这个服务了。我放在我服务器上的地址就是http://www.ibaiy.com/rpg.aspx 只是我不明白为什么有时候服务器可以运行，就可以完美支持这个网游，但有时候又不行，连FLASH都显示不出来。
我把文件修改了一下，把聊天和换头发都做上去了。还把页面做成全屏的。试着点点吧，兴许运气好就可以看到^_^