由于需要将某些指定网站的cookie删除,不被网站记录登录的痕迹,百度了很久,都是利用一些软件带有界面,没有提供带命令行方式的操作方法,不能做到自动化删除指定网站的cookie,网上流传的都是删除所有cookie的批处理,近日查看批处理相关资料,结合自己的需要编写了这个小得批处理程序,希望对由此需要的朋友有所帮助。
源代码如下:
rem delck.bat or delck.cmd 这就是批处理的文件名
rem 关闭回显功能,不让它出来干扰画面
@echo off
rem 设置find和 taskkill 的执行路径,win7有此bug,XP可以识别
set cmdpath=%systemroot%\system32
rem 判断windows系统版本,确定cookie的位置
ver | %cmdpath%\find /i "6.1">nul
if %errorlevel% equ 0 (goto win7)
ver | %cmdpath%\find /i "5.1">nul
if %errorlevel% equ 0 (goto winXP)
:win7
echo.
cd /D %userprofile%\AppData\Roaming\Microsoft\Windows\Cookies
echo 您的系统是 :Windows 7
goto begin
:winXP
echo.
cd /D %userprofile%\Cookies
echo 您的系统是 :Windows XP
:begin
if "%1"=="" goto usage
rem 需要关闭浏览器才可以完全删掉指定的cookie,这里以360和ie为例,可以根据需要添加其他的浏览器
echo =======正在关闭浏览器=======
@%systemroot%\system32\taskkill /im 360se.exe >nul
@%systemroot%\system32\taskkill /im iexplore.exe>nul
echo =======已经关闭浏览器=======
:delck1
echo.
echo =======正在清除%1的cookie=======
for %%i in (*.txt) do type %%i | %systemroot%\system32\find.exe /i "%1" && del %%i
echo =======清除%1的cookie完毕=======
if "%2"=="" goto end
:delck2
echo.
echo =======正在清除%2的cookie=======
for %%i in (*.txt) do type %%i | %systemroot%\system32\find.exe /i "%2" && del %%i
echo =======清除%2的cookie完毕=======
goto end
:usage
echo.
echo 使用方法:delck cookie关键词1 cookie关键词2
goto ender
:end
echo.
echo 清除cookie完毕,按任意键退出!
pause >nul
:ender
使用时输入 delck cookie关键词1 cookie关键词2,例如:delck baidu taobao 就可以同时删除百度和淘宝的cookie,当然这个还可以改为同时删除3个,4个以及更多的指定网站的cookie.
联系客服